Question

如何将SUM（）函数应用于每个hours节点？我将这个transfomred XML保存为Excel，我希望它能嵌入SUM（）函数。在研究之后，似乎有很多方法可以做到这一点，但没有一个真正适用于我的问题。

XSL：

<?xml version="1.0" encoding="UTF-8"?>

<xsl:stylesheet version="2.0"
xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/">
        <html>
            <body>
                <img src="../images/company_logo.png"></img>
                <p>Company: <xsl:value-of select="companies/company[1]/companyName"/></p>
                <p>Date: <xsl:value-of select="companies/company[1]/startDate"/> to <xsl:value-of select="companies/row[last()]/endDate"/></p>
                <table>
                    <xsl:for-each select="company/row">
                    <tr>
                        <td>ID:</td>
                        <td><xsl:value-of select="serviceID"/></td>
                        <td>Hours:</td>
                        <td><xsl:value-of select="hours"/></td>
                    </tr>
                    </xsl:for-each>
                </table>
            </body>
        </html>
    </xsl:template>
</xsl:stylesheet>

XML

<company>
    <companyName>Cool Beans</companyName>
    <serviceID>1</serviceID>
    <startDate>01-01-2014 00:00:00</startDate>
    <endDate>01-02-2014 00:00:00</endDate>
    <hours>2</hours>
</company>

Answer 1

假设你有一个像这样的文件：

<companies name="My Companies">
    <company>
        <companyName>Cool Beans</companyName>
        <serviceID>1</serviceID>
        <startDate>01-01-2014 00:00:00</startDate>
        <endDate>01-02-2014 00:00:00</endDate>
        <hours>2</hours>
    </company>
    <company>
        <companyName>Hot Beans</companyName>
        <serviceID>2</serviceID>
        <startDate>01-01-2014 00:00:00</startDate>
        <endDate>01-02-2014 00:00:00</endDate>
        <hours>2</hours>
    </company>
    <company>
        <companyName>Evil Beans</companyName>
        <serviceID>3</serviceID>
        <startDate>01-03-2014 00:00:00</startDate>
        <endDate>01-04-2014 00:00:00</endDate>
        <hours>2</hours>
    </company>
</companies>

您必须生成有效的XLS或XSLX文件。我将使用[此Office 2003]（http://en.wikipedia.org/wiki/Microsoft_Office_XML_formats）格式作为示例（XLS）。

您的样式表必须声明您可能需要的所有前缀和名称空间，以质量电子表格中的属性和元素。您只需在XSLT中声明它们，它们就会被复制到结果文件中：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0"
    xmlns="urn:schemas-microsoft-com:office:spreadsheet"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt"
    xmlns:x="urn:schemas-microsoft-com:office:excel"
    xmlns:ss="urn:schemas-microsoft-com:office:spreadsheet"> ... </xsl:stylesheet>

您需要生成一个mso-application 处理指令，它应该出现在文档根元素之前。我们可以为此创建一个模板：

<xsl:template match="/">
    <xsl:processing-instruction name="mso-application">progid="Excel.Sheet"</xsl:processing-instruction>
    <Workbook>
        <xsl:apply-templates select="companies" />
    </Workbook>
</xsl:template>

此模板将处理一次，因为它与root匹配。它将调用companies元素，该元素将处理样式表的其余部分。这是一个最小的模板。您也可以放置元数据标签，样式等。

我们也可以将工作表代码放在根模板中。我决定把它分开，以避免大模板。由于只有一个companies节点，因此只会处理一次。它将创建WorkSheet，Table并调用其他模板来处理各个行和单元格。

<xsl:template match="companies"> <Worksheet ss:Name="{@name}"> <Table x:FullColumns="1" x:FullRows="1"> <Row> <xsl:apply-templates select="company[1]/*" mode="headers"/> </Row> <xsl:apply-templates select="company" /> <Row> <Cell ss:Index="4"><Data ss:Type="String">Total:</Data></Cell> <Cell ss:Formula="=SUM(R[-{count(company)}]C:R[-1]C)"> <Data ss:Type="Number"></Data> </Cell> </Row> </Table> </Worksheet> </xsl:template>

第一个Row将包含标题。由于XML源没有头名，我们将使用第一个company的子元素 names 创建它们（在单独的模板中完成）。单个行和单元格也将在单独的模板中处理，但在这里我们创建 last 行。我们在第4列放置一个单元格以打印文本“Total：”，然后在跟随行中插入一个Excel公式，该公式将对之前的 n 行求和，其中 n 是总company个节点（R(-n)C:R(-1)C将评估为E2:E4，其内容如下：“来自此行 - count（公司）到这一行 - 1“）。

其他模板使用ss:Type信息为每个行和数据单元创建代码（您要求的字段必须为Number类型。）

以下是完整的样式表：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns="urn:schemas-microsoft-com:office:spreadsheet" xmlns:msxsl="urn:schemas-microsoft-com:xslt" xmlns:x="urn:schemas-microsoft-com:office:excel" xmlns:ss="urn:schemas-microsoft-com:office:spreadsheet"> <xsl:output method="xml" indent="yes" /> <xsl:template match="/"> <xsl:processing-instruction name="mso-application">progid="Excel.Sheet"</xsl:processing-instruction> <Workbook> <xsl:apply-templates select="companies" /> </Workbook> </xsl:template> <xsl:template match="companies"> <Worksheet ss:Name="{@name}"> <Table x:FullColumns="1" x:FullRows="1"> <Row> <xsl:apply-templates select="company[1]/*" mode="headers"/> </Row> <xsl:apply-templates select="company" /> <Row> <Cell ss:Index="4"><Data ss:Type="String">Total:</Data></Cell> <Cell ss:Formula="=SUM(R[-{count(company)}]C:R[-1]C)"> <Data ss:Type="Number"></Data> </Cell> </Row> </Table> </Worksheet> </xsl:template> <xsl:template match="company[1]/*" mode="headers"> <Cell> <Data ss:Type="String"> <xsl:value-of select="name()" /> </Data> </Cell> </xsl:template> <xsl:template match="company"> <Row> <xsl:apply-templates select="*" /> </Row> </xsl:template> <xsl:template match="companyName|serviceID|startDate|endDate"> <Cell> <Data ss:Type="String"> <xsl:value-of select="."/> </Data> </Cell> </xsl:template> <xsl:template match="hours"> <Cell> <Data ss:Type="Number"> <xsl:value-of select="."/> </Data> </Cell> </xsl:template> </xsl:stylesheet>

将结果保存在扩展名为.xls的文件中（不 .xslx），然后在Excel中打开。您将有一个电子表格，其中包含名为“我的公司”的工作表，表格列中的每个字段以及作为Excel公式计算的最后一行/列的总小时数。

这是一个 fiddle ，其中包含应用于我在本答案开头提供的来源的样式表（可能类似于您的来源）。以下是结果列表：

<?xml version="1.0" encoding="UTF-8"?> <?mso-application progid="Excel.Sheet"?> <Workbook xmlns="urn:schemas-microsoft-com:office:spreadsheet" xmlns:msxsl="urn:schemas-microsoft-com:xslt" xmlns:x="urn:schemas-microsoft-com:office:excel" xmlns:ss="urn:schemas-microsoft-com:office:spreadsheet"> <Worksheet ss:Name="My Companies"> <Table x:FullColumns="1" x:FullRows="1"> <Row> <Cell> <Data ss:Type="String">companyName</Data> </Cell> <Cell> <Data ss:Type="String">serviceID</Data> </Cell> <Cell> <Data ss:Type="String">startDate</Data> </Cell> <Cell> <Data ss:Type="String">endDate</Data> </Cell> <Cell> <Data ss:Type="String">hours</Data> </Cell> </Row> <Row> <Cell> <Data ss:Type="String">Cool Beans</Data> </Cell> <Cell> <Data ss:Type="String">1</Data> </Cell> <Cell> <Data ss:Type="String">01-01-2014 00:00:00</Data> </Cell> <Cell> <Data ss:Type="String">01-02-2014 00:00:00</Data> </Cell> <Cell> <Data ss:Type="Number">2</Data> </Cell> </Row> <Row> <Cell> <Data ss:Type="String">Hot Beans</Data> </Cell> <Cell> <Data ss:Type="String">2</Data> </Cell> <Cell> <Data ss:Type="String">01-01-2014 00:00:00</Data> </Cell> <Cell> <Data ss:Type="String">01-02-2014 00:00:00</Data> </Cell> <Cell> <Data ss:Type="Number">2</Data> </Cell> </Row> <Row> <Cell> <Data ss:Type="String">Evil Beans</Data> </Cell> <Cell> <Data ss:Type="String">3</Data> </Cell> <Cell> <Data ss:Type="String">01-03-2014 00:00:00</Data> </Cell> <Cell> <Data ss:Type="String">01-04-2014 00:00:00</Data> </Cell> <Cell> <Data ss:Type="Number">2</Data> </Cell> </Row> <Row> <Cell ss:Index="4"> <Data ss:Type="String">Total:</Data> </Cell> <Cell ss:Formula="=SUM(R[-3]C:R[-1]C)"> <Data ss:Type="Number"/> </Cell> </Row> </Table> </Worksheet> </Workbook>

这是在Excel for Mac 2011中加载后的结果文件的屏幕截图：

单击位置Row(5)Col(5)或E5上的字段计算总计，您应该看到它存储了Excel公式，该公式使用{{1}中的数据正确添加3字段（Row(5-3)Col(5):Row(5-1)Col(5)）：

将Excel的SUM（）添加到XSLT结果页面？

1 个答案: