Question

对于我们被告知的任务，可以使用GraphViz输出图表以获得更多功能。这就是我们获得的所有信息。

赋值是perl输出XML。我很确定我可以输出代码，我只需要知道如何从那里处理它。

我做过一些研究，我一直试图测试一些简单的代码。

对于DOTML我在http://www.martin-loetzsch.de/DOTML/

中找到了这个简单的例子

<graph  file-name="graphs/nice_graph" rankdir="LR">

    <node   id="a" label="node1" fontsize="9" fontname="Arial"/>
    <node   id="b" label="node2" fontsize="9" fontname="Arial"/>
    <node   id="c" label="node3" fontsize="9" fontname="Arial"/>
    <node   id="d" label="node4" fontsize="9" fontname="Arial"/>
    <edge   from="a" to="b" fontname="Arial" fontsize="9" label="edge1"/>
    <edge   from="a" to="c" fontname="Arial" fontsize="9" label="edge2"/>
    <edge   from="b" to="c" fontname="Arial" fontsize="9" label="edge3"/>
    <edge   from="b" to="d" fontname="Arial" fontsize="9" label="edge4"/>
    <edge   from="c" to="d" fontname="Arial" fontsize="9" label="edge5"/>
</graph>

我尝试使用此

从命令行运行它

dot -Tps graph1.dot -o graph1.ps

和

dot -Tps graph1.dot -o graph

会抛出此错误

Error: graph_test.dotml:1: syntax error near line 1
context: <graph         file-name="graph" >>>  rankdir="LR"> <<<

我也尝试过相同的graphml文件，这里是文件的头部

<?xml version="1.0" encoding="UTF-8"?>
<graphml xmlns="http://graphml.graphdrawing.org/xmlns"  
    xmlns:xsi="http://www.w3.org/2001/XMLSchema-instance"
    xsi:schemaLocation="http://graphml.graphdrawing.org/xmlns
     http://graphml.graphdrawing.org/xmlns/1.0/graphml.xsd">
  <graph id="G" edgedefault="undirected">

基本上会抛出相同的错误

Error: simple.graphml:1: syntax error near line 1
context: <?xml version="1.0" >>>  encoding="UTF-8"?> <<

如果有人能够至少指导我在哪里获得一些好的，那么如何实施它的基本指示就会很好。干杯

编辑：我们只能使用默认的CPAN模块

Answer 1

您需要将GraphML转换为DOT。您可以在此处获得完整的XSLT样式表：

http://graphml.graphdrawing.org/download.html

要转换您发布的XML图形作为示例，您可以像这样一个XSLT样式表（这是非常有限的，只能用于非常简单的图形 - 我用它作为教学示例）：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="graph|digraph">
        <xsl:value-of select="name()"/>
        <xsl:text> {&#xa;</xsl:text>
        <xsl:apply-templates select="@rankdir|node()"/>
        <xsl:text>}</xsl:text>
    </xsl:template>

    <xsl:template match="@rankdir">
        <xsl:text>rankdir = </xsl:text>
        <xsl:value-of select="."/>
        <xsl:text>;&#xa;</xsl:text>
    </xsl:template>

    <xsl:template match="node">
        <xsl:value-of select="@id"/>
        <xsl:if test="@*[not(name()='id')]">
            <xsl:text> [</xsl:text>
            <xsl:for-each select="@*[not(name()='id')]">
                <xsl:value-of select="name()"/>
                <xsl:text>=&quot;</xsl:text>
                <xsl:value-of select="."/>
                <xsl:text>&quot;</xsl:text>
                <xsl:if test="not(position()=last())">
                    <xsl:text>, </xsl:text>
                </xsl:if>
            </xsl:for-each>
            <xsl:text>];&#xa;</xsl:text>
        </xsl:if>
    </xsl:template>

    <xsl:template match="edge">
        <xsl:value-of select="@from"/>
        <xsl:choose>
            <xsl:when test="parent::*[name()='graph']">
                <xsl:text> -- </xsl:text>
            </xsl:when>
            <xsl:otherwise>
                <xsl:text> -> </xsl:text>
            </xsl:otherwise>
        </xsl:choose>
        <xsl:value-of select="@to"/>
        <xsl:if test="@*[not(name()='from')][not(name()='to')]">
            <xsl:text> [</xsl:text>
            <xsl:for-each select="@*[not(name()='from')][not(name()='to')]">
                <xsl:value-of select="name()"/>
                <xsl:text>=&quot;</xsl:text>
                <xsl:value-of select="."/>
                <xsl:text>&quot;</xsl:text>
                <xsl:if test="not(position()=last())">
                    <xsl:text>, </xsl:text>
                </xsl:if>
            </xsl:for-each>
            <xsl:text>];&#xa;</xsl:text>
        </xsl:if>
    </xsl:template>

</xsl:stylesheet>

在这个fiddle中，我使用它将您的GraphML文档转换为可以与命令行DOT应用程序一起使用的DOT文档：

graph {
rankdir = LR;
a [label="node1", fontsize="9", fontname="Arial"];
b [label="node2", fontsize="9", fontname="Arial"];
c [label="node3", fontsize="9", fontname="Arial"];
d [label="node4", fontsize="9", fontname="Arial"];
a -- b [fontname="Arial", fontsize="9", label="edge1"];
a -- c [fontname="Arial", fontsize="9", label="edge2"];
b -- c [fontname="Arial", fontsize="9", label="edge3"];
b -- d [fontname="Arial", fontsize="9", label="edge4"];
c -- d [fontname="Arial", fontsize="9", label="edge5"];
}

将上面的代码重命名为something.dot并使用Graphviz或dot运行它，它应生成图表。

您可以使用Lib::XSLT CPAN模块运行XSLT。

graphml或dotml如何

1 个答案: