Question

我有一个实体（地图）矢量，我已经将这个矢量过滤到具有特定键的那些实体。然后我应用一个函数来更新这些实体中的一些值，现在有一个我希望与原始超集合并的子集。

world     [{a} {b} {c} {d} {e}]
a         [{b} {d} {e}]            ; (filter matches? world)
b         [{b'} {d'} {e'}]         ; (map func a)
new-world [{a} {b'} {c} {d'} {e'}] ; (merge world b)

如何将更新b与原始world合并？

我的地图结构是：

{:id identity
 :attrs {:property1 {:param1 value
                     :param2 value}
         :property2 {}}

可以有可变数量的属性。属性可以有0（{}）或更多参数。地图中唯一要改变的部分是值，只有部分值。

我必须查看每个地图以识别它，然后相应地合并？什么是惯用的方法呢？

Clojure map function可以采用多个序列，但不会将我的子集b与整个超集world进行比较，只有b个世界实体，并在b耗尽后停止。

> (map #(str %1 " " %2) [1 2 3 4 5] [6 7 8])
("1 6" "2 7" "3 8")

我是否首先为我的数据选择了错误的结构？如果没有矢量而只有一张地图，我会更好吗？

{:entid1
   {:property1 {:param1 value :param2 value}
    :property2 {}}
 :entid2
   {:property1 {:param1 value :param2 value}
    :property2 {:param1 value}
    :property3 {:param1 value :param2 value :param3 value}}}

This question看起来很相似，但没有正确合并我的矢量。

真实世界的实施

我的实际代码是part of a game I'm writing以熟悉Clojure（本例中为ClojureScript）。

游戏状态（世界）如下：

[{:id :player,
  :attrs
    {:gravity {:weight 10},
     :jump {:height 60, :falling false, :ground true},
     :renderable {:width 37, :height 35},
     :position {:x 60, :y 565},
     :walk {:step 4, :facing :right},
     :input {},
     :solid {:blocked false}}}
 {:id wall1,
  :attrs
    {:solid {},
     :position {:x 0, :y 0},
     :renderable {:width 20, :height 600}}}
 {:id wall2,
  :attrs
    {:solid {},
     :position {:x 780, :y 0},
     :renderable {:width 20, :height 600}}}
 {:id platform3,
  :attrs
    {:solid {},
     :position {:x 20, :y 430},
     :renderable {:width 600, :height 20}}}]

我在每个动画帧上更新世界，然后重新渲染画布。

(defn game-loop []
  (ui/request-frame game-loop)
  (-> world
      system/update!
      ui/render))

system/update!是：

(defn update! [world]
  (let [new-world (->> @world
                      (phys/move @player/input-cmd))]
    (player/clear-cmd)
    (reset! world new-world)
    @world))

我的计划是让一系列系统在线程最后一个宏中更新世界。我正在撰写phys/move。

这意味着系统必须更新世界，而不是仅仅返回它们对世界的影响（变化的向量）。

我正在考虑让system/update!功能管理对世界的影响（应用更新）是否更易于管理。因此系统只返回他们的更改列表。类似的东西：

(defn update! [world]
  (let [updates []
        game @world]
     (conj updates (phys/move @player/input-cmd game))
     (conj updates (camera/track :player game))
     ; etc.
     (reset! world
       (map #(update-world updates %) world))
     @world))

重复的(conj updates (func world))虽然感觉很笨拙。这可能不仅仅是在系统函数中合并更新（或返回修改后的实体）。

如何在我的系统函数（phys/move，camera/track）和子系统函数（walk，jump）之间优雅地传递状态更改？

我只是将Joaquin的地图应用于我的move系统：

(ns game.phys)

(def step 4)
(def height 50)

(defn walk?
  "is this a walk command?"
  [cmd]
  (#{:left :right} cmd))

(defn walks?
  "update? equivalent"
  [entity]
  (contains? (:attrs entity) :position))

(defn walk
  [cmd entity]
  (if (walks? entity)
    (let [x (get-in entity [:attrs :position :x]
          op (if (= cmd :left) - +)
          update {:attrs {:position {:x (op x step)}
                          :walk     {:facing cmd}}}]
      (merge entity update))
    entity))

; cmd is a deref'ed atom that holds player input commands
; e.g. :left :right: :jump
(defn move
  [cmd world]
  (cond
    (walk? cmd) (map #(walk input-cmd %) world)
    (jump? cmd) (map #(jump height %) world)
    :else world))

Answer 1

它比所有的更简单（有一个地图矢量是非常常见的，它可能适合你的问题）。不要做过滤器然后做地图，只需做一张地图：

(defn update? [entity] ...)
(defn update-entity [entity] ...)

(defn update-world [world]
  (let [update #(if (matches? %) (update-entity %) %)]
    (map update world)))

这种更新某种东西或者只是保留原样的模式是非常常见的，并且使得更新某些东西的函数返回更新的东西或者旧的东西（如果它什么也不做）是不恰当的，所以最后它会是这样的：

(defn update-entity?
  "Predicate that returns if an entity needs updating"
  [entity] ...)

(defn update-entity
  "Updates an entity if it is needed.
   Otherwise returns the unchanged entity"
  [entity]
  (if (update-entity? entity)
    (assoc entity :something :changed)
    entity))

(defn update-world [world]
  (map update-entity world))

你可以在这个蛇游戏的游戏逻辑中看到这种行为的一些例子：

https://github.com/joakin/cnake/blob/master/src/cnake/game.cljs#L54-L66
https://github.com/joakin/cnake/blob/master/src/cnake/game.cljs#L102-L114

在Clojure中，我如何合并两个地图矢量？

1 个答案: