Question

假设：

带数据的文件：

<doc>
     <a>some text(<p>text here</p>) or blank</a>
     <b>same</b>
</doc>

具有默认值的文件：

<doc>
     <a><p>Dummy text</p></a>
     <b><p>Dummy text</p></b>
</doc>

我这个xslt从第二个文件中获取默认值：

$ file =默认值的文件路径

<a>
    <xsl:choose>
        <xsl:when test="//a!= ''">
            <xsl:copy-of select="//a/p" />
        </xsl:when>
        <xsl:otherwise>
              <xsl:copy-of select="document($file)//a/p" />
        </xsl:otherwise>
    </xsl:choose>
</a>

有了它，它运作良好，唯一的问题是我想通过 xml节点进行迭代，并制作一个自动化流程来提高可扩展性每次节点输入相同条件时节省时间。但我无法找到一种方法将 document（）函数与 xpath ，文档（$ file）$ nodexpath 的变量一起使用不行。

我可能会遗漏一些东西，最近刚刚开始使用xslt，如果有人能给我一些建议我会非常感激。

提前致谢。

修改实际数据类似于这样的xml，它可以有更深的水平。

   <doc>
       <object>
          <group1> 
              <a>(<p>text here</p> or blank)</a>
              <b>(<p>text here</p> or blank)</b>
              <c>
                 <c1>(<p>text here</p> or blank)</c1>
                 <c2>(<p>text here</p> or blank)</c2>
              </c>
          </group1>
          <group2>
              <d>(<p>text here</p> or blank)</d>
          </group2>
       </object>
    </doc>

Answer 1

您可以尝试匹配任何不包含子元素或文本的元素，并根据名称提取默认值。

根据您的示例，似乎没有理由尝试匹配xpath。如果您的实际数据更复杂，请更新您的问题，我可以更新我的答案。

示例：

XML输入（添加空a和b以获取默认值。）

<doc>
    <a>some text(<p>text here</p>) or blank</a>
    <a/>
    <b>same</b>
    <b/>
</doc>

<强> so_defaults.xml

<doc>
    <a><p>Dummy text for "a".</p></a>
    <b><p>Dummy text for "b".</p></b>
</doc>

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:variable name="defaults" select="document('so_defaults.xml')"/>

    <xsl:template match="@*|node()">
        <xsl:copy>
            <xsl:apply-templates select="@*|node()"/>
        </xsl:copy>
    </xsl:template>

    <xsl:template match="*[not(*) and not(text())]">
        <xsl:copy>
            <xsl:apply-templates select="$defaults/*/*[name()=name(current())]/*"/>
        </xsl:copy>
    </xsl:template>

</xsl:stylesheet>

<强>输出

<doc>
   <a>some text(<p>text here</p>) or blank</a>
   <a>
      <p>Dummy text for "a".</p>
   </a>
   <b>same</b>
   <b>
      <p>Dummy text for "b".</p>
   </b>
</doc>

Answer 2

我终于解决了，我在这里发布我的解决方案，感谢Daniel的回答，它对我帮助很大：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:template match="/*">
        <doc xml:lang="es">
            <object>
                <xsl:apply-templates select="*"/>
            </object>
        </doc>
    </xsl:template> 

    <xsl:template match="*">
        <xsl:copy>
            <xsl:choose>
              <xsl:when test="current() != ''">
                <xsl:choose>
                    <xsl:when test="self::p">
                        <xsl:copy-of select="node()"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="*"/>
                    </xsl:otherwise>
                </xsl:choose>
              </xsl:when>
              <xsl:otherwise>
                <xsl:variable name="file" select="document('template.xml')"/>
                <xsl:copy-of select ="$file//*[name()=name(current())]/p"/>
              </xsl:otherwise>
            </xsl:choose>
        </xsl:copy>
    </xsl:template>
</xsl:stylesheet>

为空节点设置另一个xml的默认值

2 个答案: