如何创建垂直颜色渐变（或除平坦水平渐变之外的任何其他角度）

Question

大家好，我第一次尝试在动作3中绘制多色渐变。

所以我从the help docs得到了这个代码，但我似乎无法得到一个垂直渐变，无论我用于旋转的公式或数字，它都会停留在默认的水平渐变上:(

我的代码：

你可以在痕迹中看到我试过的旋转代码......

package
{
import flash.display.DisplayObject;
import flash.display.GradientType;
import flash.display.SpreadMethod;
import flash.display.MovieClip;
import flash.display.Graphics;
import flash.display.Sprite;
import flash.display.Shape;
import flash.geom.Matrix;
import flash.events.*;

public class MyGradient extends MovieClip
{
    private var colorHolder:MovieClip = new MovieClip();
    private var colorGrad:MovieClip = new MovieClip();
    private var fillType:String     = GradientType.LINEAR;
    private var colors:Array        = [0xFF0000, 0x4F8EEC];
    private var alphas:Array        = [1, 1];
    private var ratios:Array        = [0x00, 0xFF];
    private var matr:Matrix         = new Matrix();
    private var spreadMethod:String = SpreadMethod.PAD;


    public function MyGradient():void
    {
        if (stage) init();
        else addEventListener(Event.ADDED_TO_STAGE, init);
    }

    private function init():void
    {
        colorHolder = new MovieClip();
        colorGrad   = new MovieClip();

        //matr.rotate(30*Math.PI/180);
        //matr.rotate(45);
        //matr.rotate(90);
        //matr.rotate(Math.PI/90);
        matr.rotate(Math.PI/9);
        matr.createGradientBox(200, 200, 0, 0, 1);
        colorGrad.graphics.beginGradientFill(fillType, colors, alphas, ratios, matr, spreadMethod);        
        colorGrad.graphics.drawRect(0,0,200,200);

        colorHolder.addChild(colorGrad);
        addChild(colorHolder);
        }

    }

}

Heavily involved更新了修正：

matr.createGradientBox(200, 200, Math.PI/2, 0, 0);

Answer 1

这行代码将旋转值设置回零：

matr.createGradientBox(200, 200, 0, 0, 1);

如果查看函数接受的参数，您将看到第三个参数是旋转。所以，请尝试以下方法：

matr.createGradientBox(200, 200, Math.PI/9, 0, 1);

另外，你有没有理由将y值翻译1个像素？

希望这会有所帮助。祝你好运！

Answer 2

尝试更改这两行的顺序，因此它将是：

matr.createGradientBox(200, 200, 0, 0, 1);
matr.rotate((Math.PI/180)*90);

Answer 3

如果您正在进行大量绘图，您还应该查看degrafa。

http://www.degrafa.org/