错误函数SQL Server插入数据

Question

这是我的功能代码：

CREATE FUNCTION [dbo].[fSubString](@pStudentID VARCHAR(1000))
RETURNS @vStringTable TABLE( StudentNo int)
AS
BEGIN
   DECLARE @pStart INT, -- for substring , start
           @pLength INT; -- Length for @pStudent

   SET @pStart = 1;
   SET @pLength = DATALENGTH(@pStudentID);

   WHILE(@pStart <= @pLength)
   BEGIN
       INSERT INTO @vStringtable    
       VALUES(SUBSTRING(@pStudentID, @pStart, CHARINDEX(',', @pStudentID, 1) - 1))

       SET @pStart = CHARINDEX(',', @pStudentID, 1) + @pStart;
   END

   RETURN
END

执行此功能

Select * from dbo.fSubString('1,4,2,3,6,5,4,3')

工作正常。

但是这个函数的执行会导致问题：

 Select * from dbo.fSubString('33,4,44,3,6,5,74,3')

Answer 1

有很多更好的方法来分割字符串。不要重新发明轮子。

请参阅Aaron Bertrand的这篇文章，了解一些知情方式。

http://sqlperformance.com/2012/07/t-sql-queries/split-strings

例如，如果您的数据是XML安全的，请使用此功能。非常适合小型数据集。请参阅文章末尾的效果指标。

CREATE FUNCTION dbo.SplitStrings_XML
(
   @List       NVARCHAR(MAX),
   @Delimiter  NVARCHAR(255)
)
RETURNS TABLE
WITH SCHEMABINDING
AS
   RETURN 
   (  
      SELECT Item = y.i.value('(./text())[1]', 'nvarchar(4000)')
      FROM 
      ( 
        SELECT x = CONVERT(XML, '<i>' 
          + REPLACE(@List, @Delimiter, '</i><i>') 
          + '</i>').query('.')
      ) AS a CROSS APPLY x.nodes('i') AS y(i)
   );
GO

以下是样本调用的结果。该函数存储在msdb中。