Question

我有Hash，其中键的值是其他Hashes。

示例：{'key' => {'key2' => {'key3' => 'value'}}}

如何迭代这个结构？

Answer 1

这个答案建立在Dave Hinton背后的思想基础之上 - 即编写一个通用子程序来构建哈希结构。这样的散列漫游器接受代码引用，并简单地为散列中的每个叶节点调用该代码。

使用这种方法，可以使用相同的散列漫游器来执行许多操作，具体取决于我们提供的回调。为了获得更大的灵活性，您需要传递两个回调 - 一个是在值是哈希引用时调用，另一个是在普通标量值时调用。 Marc Jason Dominus的优秀着作Higher Order Perl更深入地探讨了这样的策略。

use strict;
use warnings;

sub hash_walk {
    my ($hash, $key_list, $callback) = @_;
    while (my ($k, $v) = each %$hash) {
        # Keep track of the hierarchy of keys, in case
        # our callback needs it.
        push @$key_list, $k;

        if (ref($v) eq 'HASH') {
            # Recurse.
            hash_walk($v, $key_list, $callback);
        }
        else {
            # Otherwise, invoke our callback, passing it
            # the current key and value, along with the
            # full parentage of that key.
            $callback->($k, $v, $key_list);
        }

        pop @$key_list;
    }
}

my %data = (
    a => {
        ab => 1,
        ac => 2,
        ad => {
            ada => 3,
            adb => 4,
            adc => {
                adca => 5,
                adcb => 6,
            },
        },
    },
    b => 7,
    c => {
        ca => 8,
        cb => {
            cba => 9,
            cbb => 10,
        },
    },
);

sub print_keys_and_value {
    my ($k, $v, $key_list) = @_;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $v, "@$key_list";
}

hash_walk(\%data, [], \&print_keys_and_value);

Answer 2

这是你想要的吗？（另）

sub for_hash {
    my ($hash, $fn) = @_;
    while (my ($key, $value) = each %$hash) {
        if ('HASH' eq ref $value) {
            for_hash $value, $fn;
        }
        else {
            $fn->($value);
        }
    }
}

my $example = {'key' => {'key2' => {'key3' => 'value'}}};
for_hash $example, sub {
    my ($value) = @_;
    # Do something with $value...
};

Answer 3

This post可能有用。

foreach my $key (keys %hash) {
    foreach my $key2 (keys %{ $hash{$key} }) {
        foreach my $key3 (keys %{ $hash{$key}{$key2} }) {
            $value = $hash{$key}{$key2}->{$key3};
            # .
            # .
            # Do something with $value
            # .
            # .
            # .
        }
    }
}

Answer 4

之前的答案显示了如何推出自己的解决方案，这至少可以做一次，这样您就能理解perl引用和数据结构的工作方式。如果您还没有，请务必仔细阅读perldoc perldsc和perldoc perlref。

但是，您不需要编写自己的解决方案--CPAN上已经有一个模块可以为您迭代任意复杂的数据结构：Data::Visitor。

Answer 5

另外，请仔细阅读perldoc perldsc。您可以深入了解哈希

Answer 6

这不是一个真正的新答案，但我想分享如何做更多只需递归打印所有哈希值，但也可以根据需要修改它们。

这是我对dave4420的答案的轻微修改该值作为引用传递给回调，因此我的回调例程然后可以修改散列中的每个值。

我还必须重建哈希，因为每个循环都会创建副本不是参考。

sub hash_walk {
   my $self = shift;
    my ($hash, $key_list, $callback) = @_;
    while (my ($k, $v) = each %$hash) {
        # Keep track of the hierarchy of keys, in case
        # our callback needs it.
        push @$key_list, $k;

        if (ref($v) eq 'HASH') {
            # Recurse.
            $self->hash_walk($v, $key_list, $callback);
        }
        else {
            # Otherwise, invoke our callback, passing it
            # the current key and value, along with the
            # full parentage of that key.
            $callback->($k, \$v, $key_list);
        }

        pop @$key_list;
        # Replace old hash values with the new ones
        $hash->{$k} = $v;
    }
}

hash_walk(\%prj, [], \&replace_all_val_strings);

sub replace_all_val_strings {
    my ($k, $v, $key_list) = @_;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $$v, "@$key_list";
    $$v =~ s/oldstr/newstr/;
    printf "k = %-8s  v = %-4s  key_list = [%s]\n", $k, $$v, "@$key_list";
}

Answer 7

foreach my $keyname (keys(%foo) {
  my $subhash = $foo{$keyname};
  # stuff with $subhash as the value at $keyname
}

Answer 8

你必须循环两遍。即。

while ( ($family, $roles) = each %HoH ) {
   print "$family: ";
   while ( ($role, $person) = each %$roles ) {
      print "$role=$person ";
   }
print "\n";
}

Answer 9

如果您使用perl作为＆＃34; CPAN解释器＆＃34;然后除了Data::Visitor和Data::Deep之外还有超级简单的Data::Traverse：

use Data::Traverse qw(traverse);

my %test_hash = (
  q => [qw/1 2 3 4/],
  w => [qw/4 6 5 7/],
  e => ["8"],
  r => { 
         r => "9"  ,
         t => "10" ,
         y => "11" ,
      } ,
);

traverse { next if /ARRAY/; print "$a => $b\n" if /HASH/ && $b > 8 } \%test_hash;

<强>输出：

t => 10
y => 11

在$a函数内部，

$b和sort()被视为特殊变量（与traverse()一样）。 Data::Traverse是一个非常简单但非常有用的模块，没有非CORE依赖项。

如何在Perl中迭代哈希（哈希）？

9 个答案: