Question

请原谅我的无知。我刚刚开始进行XSL和XML转换。

我从供应商处收到xml数据。我只需要包含某些＆＃34; ID＆＃34;在我的转变中。我还需要添加一个＆＃34;显示名称＆＃34;基于ID到最终输出。我可以手动将必要的ID和显示名称添加到XSL中。

XML ex。

<root>
  <DATA>
    <ID>rd_bl</ID> 
    <travel>15</travel<
    <delay>7</delay>
  </DATA>
  <DATA>
    <ID>yl_gr</ID> 
    <travel>18</travel<
    <delay>9</delay>
  </DATA>
  <DATA>
    <ID>pu_gr</ID> 
    <travel>17</travel<
    <delay>6</delay>
  </DATA>
</root>

我想写一个ID列表和＆＃34;显示名称＆＃34;在xsl中 - 只包含列出ID的记录。

ID - 显示名称

rd_bl - 红色到蓝色

pu_gr - 紫色到绿色

在此示例中，来自yl_gr的数据将被忽略，并且不会显示在转换中。

非常感谢任何帮助。

谢谢！

Answer 1

这是一个简单的样式表，用于检查ID是否在允许的ID列表中，并在输出中使用“显示名称”。

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

  <xsl:variable name="desired-ids">
    <id name="rd_bl">Red to Blue</id>
    <id name="pu_gr">Purple to Green</id>
  </xsl:variable>

  <xsl:template match="root">
    <root>
      <xsl:apply-templates />
    </root>
  </xsl:template>

  <xsl:template match="DATA">
    <xsl:variable name="current-id" select="ID/text()" />
    <xsl:if test="$desired-ids/id[@name=$current-id]">
      <entry>
        <name>
          <xsl:value-of select="$desired-ids/id[@name=$current-id]" />
        </name>
        <travel>
          <xsl:value-of select="travel" />
        </travel>
        <delay>
          <xsl:value-of select="delay" />
        </delay>
      </entry>
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

在更正结束标记错误后使用示例XML输出：

<root>
  <entry>
    <name>Red to Blue</name>
    <travel>15</travel>
    <delay>7</delay>
  </entry>
  <entry>
    <name>Purple to Green</name>
    <travel>17</travel>
    <delay>6</delay>
  </entry>
</root>

编辑：如果您遇到XSL 1.0：

<?xml version="1.0"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">

  <xsl:variable name="desired-ids">rd_bl="Red to Blue" pu_gr="Purple to Green"</xsl:variable>

  <xsl:template match="root">
    <root>
      <xsl:apply-templates />
    </root>
  </xsl:template>

  <xsl:template match="DATA">
    <xsl:variable name="current-id" select="ID/text()" />
    <xsl:variable name="id-with-equals" select="concat($current-id, '=')" />
    <xsl:if test="contains($desired-ids, $id-with-equals)">
      <xsl:variable name="id-with-open-quote" select="concat($id-with-equals, '&quot;')" />
      <xsl:variable name="display-name" select="substring-before(substring-after($desired-ids, $id-with-open-quote), '&quot;')" />
      <entry>
        <name>
          <xsl:value-of select="$display-name" />
        </name>
        <travel>
          <xsl:value-of select="travel" />
        </travel>
        <delay>
          <xsl:value-of select="delay" />
        </delay>
      </entry>
    </xsl:if>
  </xsl:template>

</xsl:stylesheet>

你可以看到它不那么优雅，它使用笨拙的字符串匹配来检查有效的ID并提取显示名称。

Answer 2

这个样式表会有帮助吗？

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:output indent="yes"/>

    <xsl:template match="/">
        <table>
            <thead>
                <th>ID</th>
                <th>Display Name</th>
            </thead>
            <tbody>
                <xsl:apply-templates select="root/DATA"/>
            </tbody>
        </table>
    </xsl:template>

    <xsl:template match="DATA">
        <xsl:choose>
            <xsl:when test="ID='rd_bl'">
                <tr>
                    <td><xsl:value-of select="ID"/></td>
                    <td>Red to Blue</td>
                </tr>
            </xsl:when>
            <xsl:when test="ID='pu_gr'">
                <tr>
                    <td><xsl:value-of select="ID"/></td>
                    <td>Purple to Green</td>
                </tr>
            </xsl:when>
        </xsl:choose>
    </xsl:template>

</xsl:stylesheet>

XML使用XSL来转换记录列表

2 个答案: