Question

我有这种XSL

<xsl:stylesheet  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes"/>

    <xsl:template match="dataroot">
        <xml><xsl:apply-templates/></xml>
    </xsl:template>

    <xsl:template match="M_17">
        <package id="{package_id}" cat="{cat}">
            <nazwa><xsl:value-of select="nazwa"/></nazwa>
            <xsl:if test="author"><author><xsl:value-of select="author"/></author></xsl:if>
            <xsl:if test="www"><www><xsl:value-of select="translate(www,'#','')"/></www></xsl:if>
            <xsl:if test="opis"><opis><xsl:value-of select="opis"/></opis></xsl:if>
            <xsl:if test="img"><img><xsl:value-of select="translate(img,'#','')"/></img></xsl:if>

            <xsl:if test="depends"><depends><xsl:value-of select="depends"/></depends></xsl:if>
            <xsl:if test="conflicts"><conflicts><xsl:value-of select="conflicts"/></conflicts></xsl:if>
            <xsl:if test="after"><after><xsl:value-of select="after"/></after></xsl:if>
            <xsl:if test="replaces"><replaces><xsl:value-of select="replaces"/></replaces></xsl:if>
        </package>
    </xsl:template>

</xsl:stylesheet>

但是当有例如。取决于此代码中显示的2个值

<depends>modload com1node</depends>

但我希望通过跟随XSL将其转换为：

<depends>modloader</depends>
<depends>com1node</depends>

这应该发生在：依赖，冲突，之后和替换

如何将这些字符串（如果它们出现在源XML中）分成简单的字符串（如我在示例中所示，每行一个）？

Core XML的一部分

<?xml version="1.0" encoding="UTF-8"?>
<dataroot xmlns:od="urn:schemas-microsoft-com:officedata" generated="2014-05-11T15:51:32">
    <Mnc_172>
        <ID>1</ID>
        <package_id>minecraft</package_id>
        <cat>lib</cat>
        <www>#http://minecraft.net/#</www>
        <nazwa>Minecraft</nazwa>
        <author>Mojang</author>
        <opis>Game - build your own world!</opis>
        <img>#/mc.png#</img>
    </Mnc_172>
    <Mnc_172>
        <ID>2</ID>
        <package_id>modloader</package_id>
        <cat>lib</cat>
        <www>#http://minecraftforum.net/topic/75440-x/#</www>
        <nazwa>ModLoader</nazwa>
        <author>Risugami</author>
        <opis>ModLoader - library to load mods</opis>
        <img>#/gen.png#</img>
        <replaces>modL forging</replaces>
    </Mnc_172>
    ...
</dataroot>

Answer 1

XML与您的XSLT不匹配：M_17与Mnc_172。无论如何，在XSLT 1.0中，您需要使用递归模板来标记内容。所以尝试改变：

<depends><xsl:value-of select="depends"/></depends>

为：

<xsl:call-template name="tokenize">
    <xsl:with-param name="text" select="depends"/>
    <xsl:with-param name="elemName" select="'depends'"/>
</xsl:call-template>

并将以下模板添加到样式表中：

<xsl:template name="tokenize">
    <xsl:param name="text"/>
    <xsl:param name="elemName"/>
    <xsl:param name="sep" select="' '"/>
    <xsl:choose>
        <xsl:when test="contains($text, $sep)">
            <xsl:element name="{$elemName}">
                <xsl:value-of select="substring-before($text, $sep)"/>
            </xsl:element>
            <!-- recursive call -->
            <xsl:call-template name="tokenize">
                <xsl:with-param name="text" select="substring-after($text, $sep)" />
                <xsl:with-param name="elemName" select="$elemName" />
            </xsl:call-template>
        </xsl:when>
        <xsl:otherwise>
            <xsl:element name="{$elemName}">
                <xsl:value-of select="$text"/>
            </xsl:element>
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

Answer 2

XSLT 2.0具有标记字符串的简单功能，但在XSLT 1.0中，您必须更具创造性。我通常会像这样攻击的方式是使用递归模板，它在第一个空格之前对文本执行某些操作，然后使用剩余文本递归调用自身，并在其用完时停止。

<xsl:stylesheet  xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output indent="yes"/>

    <xsl:template match="dataroot">
        <xml><xsl:apply-templates/></xml>
    </xsl:template>

    <xsl:template match="M_17">
        <package id="{package_id}" cat="{cat}">
            <nazwa><xsl:value-of select="nazwa"/></nazwa>
            <xsl:if test="author"><author><xsl:value-of select="author"/></author></xsl:if>
            <xsl:if test="www"><www><xsl:value-of select="translate(www,'#','')"/></www></xsl:if>
            <xsl:if test="opis"><opis><xsl:value-of select="opis"/></opis></xsl:if>
            <xsl:if test="img"><img><xsl:value-of select="translate(img,'#','')"/></img></xsl:if>

            <xsl:apply-templates select="depends | conflicts | after | replaces" />
        </package>
    </xsl:template>

    <xsl:template match="depends | conflicts | after | replaces">
        <xsl:param name="text" select="concat(normalize-space(), ' ')" />
        <xsl:if test="$text">
            <xsl:copy>
                <xsl:value-of select="substring-before($text, ' ')" />
            </xsl:copy>
            <xsl:apply-templates select=".">
                <xsl:with-param name="text" select="substring-after($text, ' ')" />
            </xsl:apply-templates>
        </xsl:if>
    </xsl:template>
</xsl:stylesheet>

这里的诀窍是我们对text参数的处理方式。最初我将其设置为concat(normalize-space(), ' ')，这意味着目标元素的整个文本

删除了前导和尾随空格
内部空格规范化为单个空格字符和
添加了一个尾随空格

所以$text最初是word1-space-word2-space-...-wordN-space

现在，我们在每个步骤中创建一个与原始元素同名的新元素，并将第一个单词$text作为其内容。然后我们递归，将在第一个空格后传递给下一步（即word2-space-...-wordN-space）。最后，我们达到了$text只是wordN-space的点，此时我们为wordN生成了一个元素，然后因为substring-after($text, ' ')为空而完成。

请注意

<xsl:copy>
    <xsl:value-of select="substring-before($text, ' ')" />
</xsl:copy>

将复制输入元素范围内的名称空间声明。这是无害的，但你可能会认为它看起来有点乱。为避免这种情况，您可以使用

<xsl:element name="{local-name()}">
    <xsl:value-of select="substring-before($text, ' ')" />
</xsl:element>

代替。

如何在XML中拆分字符串

2 个答案: