Question

对于我的新程序，我想回应一个网页的代码。我搜索谷歌和Stack Overflow但没有发现这样的东西。我不想使用像URL2FILE这样的外部程序。

Answer 1

所以你想在控制台行显示网页的源代码吗？

在Linux中，您可以使用GET google.com。

Answer 2

下面的批处理文件显示在屏幕参数中给出的网页的HTML代码中，所以我认为这是该主题的解决方案。

@if (@CodeSection == @Batch) @then

@echo off
rem Start explorer with the web page and wait for it to initialize
start "" Explorer.exe %1
timeout /T 5 > NUL
rem Send to Explorer: Alt-V (View tab)...
CScript //nologo //E:JScript "%~F0" "%%V"
timeout /T 1 > NUL
rem ... followed by S (Source)
CScript //nologo //E:JScript "%~F0" "S"
goto :EOF

@end

WScript.CreateObject("WScript.Shell").SendKeys(WScript.Arguments(0));

以这种方式使用以前的程序：

test.bat http://www.google.com

有关详细信息，请参阅this post。

Answer 3

此代码来自上一个问题，该问题仅需要对添加的页面源代码的“显示”进行对服务器的查询（在注释中链接）。

@if (@This==@IsBatch) @then
@echo off
rem **** batch zone *********************************************************

    setlocal enableextensions disabledelayedexpansion

    rem Batch file will delegate all the work to the script engine 
    if not "%~1"=="" (
        cscript //E:JScript "%~dpnx0" %1
    )

    rem End of batch area. Ensure batch ends execution before reaching
    rem javascript zone
    exit /b

@end
// **** Javascript zone *****************************************************

    // Instantiate the needed component to make url queries
    var http = WScript.CreateObject('Msxml2.XMLHTTP.6.0');

    // Retrieve the url parameter
    var url = WScript.Arguments.Item(0)

    // Make the request

    http.open("GET", url, false);
    http.send();

    // If we get a OK from server (status 200), echo data to console

    if (http.status === 200) WScript.StdOut.Write(http.responseText);

    // All done. Exit
    WScript.Quit(0);

它只是一个混合批处理/ javascript文件。保存为callurl.cmd并称为callurl "http://www.google.es"，它会按照您的要求执行。没有错误检查appart来自正确的响应，没有帖子，只是一个骨架。

是否可以在批处理文件中显示网页的HTML代码？

3 个答案: