Question

如果我不小心关闭了Emacs中的 scratch 缓冲区，我该如何创建一个新的 scratch 缓冲区？

Answer 1

GNU Emacs默认绑定：

C-x b *scratch* RET

或者，更详细的

M-x switch-to-buffer *scratch* RET

*scratch*缓冲区是启动时选择的缓冲区，具有主模式Lisp Interaction。注意：*scratch*缓冲区的模式由变量initial-major-mode控制。

通常，您可以根据需要创建任意数量的“临时”缓冲区，并根据您的选择命名它们。

C-x b NAME RET

切换到缓冲区NAME，如果它不存在则创建它。在使用 Cx Cw （或 Mx write-file RET <之前，新缓冲区与磁盘上的文件无关/ kbd>）选择应保存的文件。

M-x text-mode RET

将当前缓冲区的主要模式更改为文本模式。要查找所有可用模式（即不需要任何新包），可以通过键入以下内容获取列表：

M-x apropos-command -mode$ RET

Answer 2

我在.emacs中添加了以下内容：

;; bury *scratch* buffer instead of kill it
(defadvice kill-buffer (around kill-buffer-around-advice activate)
  (let ((buffer-to-kill (ad-get-arg 0)))
    (if (equal buffer-to-kill "*scratch*")
        (bury-buffer)
      ad-do-it)))

如果我不想看到 scratch 缓冲区，我按下Cx Ck，但它不会杀死它，只是放在缓冲区列表的末尾，所以下次我需要它不必创建新的。

Answer 3

this EmacsWiki page上有很多提示。

这是第一个：

重新创建临时缓冲区的一个非常简单的功能：

(defun create-scratch-buffer nil
   "create a scratch buffer"
   (interactive)
   (switch-to-buffer (get-buffer-create "*scratch*"))
   (lisp-interaction-mode))

Answer 4

C-x b *scratch*在启用iswitchb模式的情况下RET RET RET。

只是C-x b *scratch*否则RET。

Answer 5

我几年前刚开始使用emacs时发现了这个问题。我不知道现在在哪里，但它总是在我的个人.el文件中有一个家。它会在谷歌搜索中弹出。

;;; Prevent killing the *scratch* buffer -- source forgotten
;;;----------------------------------------------------------------------
;;; Make the *scratch* buffer behave like "The thing your aunt gave you,
;;; which you don't know what is."
(save-excursion
  (set-buffer (get-buffer-create "*scratch*"))
  (make-local-variable 'kill-buffer-query-functions)
  (add-hook 'kill-buffer-query-functions 'kill-scratch-buffer))

(defun kill-scratch-buffer ()
  ;; The next line is just in case someone calls this manually
  (set-buffer (get-buffer-create "*scratch*"))

  ;; Kill the current (*scratch*) buffer
  (remove-hook 'kill-buffer-query-functions 'kill-scratch-buffer)
  (kill-buffer (current-buffer))

  ;; Make a brand new *scratch* buffer
  (set-buffer (get-buffer-create "*scratch*"))
  (lisp-interaction-mode)
  (make-local-variable 'kill-buffer-query-functions)
  (add-hook 'kill-buffer-query-functions 'kill-scratch-buffer)

  ;; Since we killed it, don't let caller do that.
  nil)
;;;----------------------------------------------------------------------

Answer 6

我曾经使用dwj的解决方案，我很高兴，直到有一天我意识到它实际上重命名暂存缓冲区（例如通过保存它）失败了。

然后我采用了这个，这对我很有用：

  (run-with-idle-timer 1 t
    '(lambda () (get-buffer-create "*scratch*")))

Answer 7

我有scratch作为打开新暂存缓冲区的交互式命令（我喜欢有几个）：

(defun scratch ()
  "create a new scratch buffer to work in. (could be *scratch* - *scratchX*)"
  (interactive)
  (let ((n 0)
        bufname)
    (while (progn
             (setq bufname (concat "*scratch"
                                   (if (= n 0) "" (int-to-string n))
                                   "*"))
             (setq n (1+ n))
             (get-buffer bufname)))
  (switch-to-buffer (get-buffer-create bufname))
  (if (= n 1) initial-major-mode))) ; 1, because n was incremented

采用自：http://everything2.com/index.pl?node_id=1038451

Answer 8

请注意，MELPA中的emacs包unkillable-scratch将执行此操作。还有scratch-persist将在会话之间自动保存和恢复缓冲区。

Answer 9

这就是我使用的 - 我有这个方便的键击。它会将您发送到*scratch*缓冲区，无论它是否已存在，并将其设置为lisp-interaction-mode

(defun eme-goto-scratch () 
  "this sends you to the scratch buffer"
  (interactive)
  (let ((eme-scratch-buffer (get-buffer-create "*scratch*")))
    (switch-to-buffer eme-scratch-buffer)
    (lisp-interaction-mode)))

Answer 10

我更喜欢让我的暂存缓冲区成为自动保存的实际文件，重新打开它就像打开文件一样简单。在启动时，我会杀死默认设置并找到我自己的默认设置。

(add-hook 'emacs-startup-hook
  (lambda ()
    (kill-buffer "*scratch*")
    (find-file "/Users/HOME/Desktop/.scratch")))

我有一个自定义的kill-buffer函数，它基本上做同样的事情 - 重新打开我个人的临时保存文件并杀死默认的scratch 如果我杀了最后一个可见的缓冲区。

我自定义了一些desktop.el函数，以便在 (kill-buffer "*scratch*")和(find-file "/Users/HOME/Desktop/.scratch")之后加载，以便在退出Emacs时最后显示的文件不会被隐藏默认情况下划痕或在启动Emacs时被我的自定义划痕隐藏。

我喜欢使用auto-save-buffers-enhanced，它会自动保存未明确排除的任何文件扩展名：

https://github.com/kentaro/auto-save-buffers-enhanced/blob/master/auto-save-buffers-enhanced.el

(require 'auto-save-buffers-enhanced) (auto-save-buffers-enhanced t) (setq auto-save-buffers-enhanced-save-scratch-buffer-to-file-p 1) (setq auto-save-buffers-enhanced-exclude-regexps '("\\.txt" "\\.el" "\\.tex"))

当我想创建一个无文件访问缓冲区时，@ paprika使用了一个稍微变化的函数：

(defun lawlist-new-buffer () "Create a new buffer -- \*lawlist\*" (interactive) (let* ( (n 0) bufname) (catch 'done (while t (setq bufname (concat "*lawlist" (if (= n 0) "" (int-to-string n)) "*")) (setq n (1+ n)) (if (not (get-buffer bufname)) (throw 'done nil)) )) (switch-to-buffer (get-buffer-create bufname)) (text-mode) ))

Answer 11

(global-set-key (kbd "C-x M-z")
                '(lambda ()
                   (interactive)
                   (switch-to-buffer "*scratch*")))

这不仅会快速切换到*scratch*缓冲区（因为我经常这样做），而是重新创建一个*scratch*缓冲区并在意外杀死它时自动启用lisp-interaction-mode。根据需要更改绑定。

Answer 12

就像docstring所说，这个函数将：

切换到临时缓冲区。如果缓冲区不存在，则创建它并将初始消息写入其中。“

这将带来一个新的临时缓冲区，看起来像初始临时缓冲区。

(defun switch-buffer-scratch ()
  "Switch to the scratch buffer. If the buffer doesn't exist,
create it and write the initial message into it."
  (interactive)
  (let* ((scratch-buffer-name "*scratch*")
         (scratch-buffer (get-buffer scratch-buffer-name)))
    (unless scratch-buffer
      (setq scratch-buffer (get-buffer-create scratch-buffer-name))
      (with-current-buffer scratch-buffer
        (lisp-interaction-mode)
        (insert initial-scratch-message)))
    (switch-to-buffer scratch-buffer)))

(global-set-key "\C-cbs" 'switch-buffer-scratch)

Answer 13

我已将目前发布的解决方案合并为一个功能：

(defun --scratch-buffer(&optional reset)
  "Get the *scratch* buffer object.
Make new scratch buffer unless it exists. 
If RESET is non-nil arrange it that it can't be killed."
  (let ((R (get-buffer "*scratch*")))
    (unless R
      (message "Creating new *scratch* buffer")
      (setq R (get-buffer-create "*scratch*") reset t))
        (when reset
          (save-excursion
            (set-buffer R)
            (lisp-interaction-mode)
            (make-local-variable 'kill-buffer-query-functions)
            (add-hook 'kill-buffer-query-functions '(lambda()(bury-buffer) nil)
          )))
    R))

要在 .emacs 中应用此功能，请使用：

(--scratch-buffer t)
(run-with-idle-timer 3 t '--scratch-buffer)

这将使暂存缓冲区首先不可破坏，如果保存，它将被重新创建。另外，我们可以使用快捷函数scratch快速调出缓冲区：

(defun scratch()
  "Switch to *scratch*.  With prefix-arg delete its contents."
  (interactive)
  (switch-to-buffer (--scratch-buffer))
  (if current-prefix-arg
      (delete-region (point-min) (point-max))
    (goto-char (point-max))))

过去，了解启动Emacs的原始启动目录已经证明是有用的。这是临时缓冲区的desktop-dirname或default-directory局部变量的值：

(defvar --scratch-directory
  (save-excursion (set-buffer "*scratch*") default-directory)
  "The `default-directory' local variable of the *scratch* buffer.")

(defconst --no-desktop (member "--no-desktop" command-line-args)
  "True when no desktop file is loaded (--no-desktop command-line switch set).")

(defun --startup-directory ()
  "Return directory from which Emacs was started: `desktop-dirname' or the `--scratch-directory'.
Note also `default-minibuffer-frame'."
  (if (and (not --no-desktop) desktop-dirname) 
      desktop-dirname
    --scratch-directory))

所以 - startup-directory 将始终返回makefile的基本目录，TODO文件等。如果没有桌面（ - no-desktop 命令行切换或没有桌面文件）--scratch-directory变量将保存目录Emacs曾经在下面启动。

Answer 14

在EmacsWiki中找到答案：http://www.emacswiki.org/emacs/RecreateScratchBuffer

(defun create-scratch-buffer nil
   "create a scratch buffer"
   (interactive)
   (switch-to-buffer (get-buffer-create "*scratch*"))
   (lisp-interaction-mode))

Answer 15

要添加到接受的答案中，如果您启用了ILO模式（并且 Cx b 之后它会自动完成，因此不允许您编写*scratch*），然后尝试：

C-x b C-b *scratch* RET

C-x b C-b *scratch* RET

Answer 16

C-x b 然后输入*scratch* ↩︎

创建一个处于lisp交互模式的新缓冲区。

在Emacs中重新打开* scratch *缓冲区？

16 个答案: