Question

背景
我一直在使用Win32_DiskDrive来查找闪存（usb笔，SD卡等），但在其他计算机上进行了一些测试后，我注意到它们并不总是被发现。所以我使用的是Win32_LogicalDisk，因为它有DriveType，我不必与两个类（例如分区）关联，先查找驱动器，然后查找驱动器号。

问题是外部硬盘在LogicalDisk中被检测为DriveType 3（本地磁盘），而在DiskDrive中的功能中没有7（支持可移动媒体）。所以我无法区分内部和外部驱动器。

问题
如何使用LogicalDisk（或者如果你真的必须使用DiskDrive）或第三种方法来区分内部硬盘和外部硬盘。

好的。问题已经回答了！
如果有人有兴趣，这是代码。

program GetWMI_USBConnectedInfo;

{$APPTYPE CONSOLE}

uses
  Windows,
  Classes,
  ActiveX,
  Variants,
  SysUtils,
  WbemScripting_TLB, // Using the .pas supplied by the wrapper as it seems to be the XP version of 1.2
  magwmi,
  magsubs1;

function CheckType(Str: string): boolean;
var
  I: Integer;
  Str2: string;
begin
  Result := False;
  for I := 1 to Length(Str) - 1 do if Str[I] = '\' then begin
    Str2 := Copy(Str, 1, I-1);
    Str2 := LowerCase(Str2);
    if (Str2 = 'usbstor') or (Str2 = 'flashmedia') then
      Result := True;
    Break;
  end;
end;

procedure  GetUSBDiskDriveInfo;
var
  I, II, III:  Integer;
  Start, Stop, Freq: Int64;
  instances, instances2, instances3: integer ;
  WmiResults, WmiResults2, WmiResults3: T2DimStrArray ;
  errstr: string ;
begin
  QueryPerformanceFrequency(Freq);
  QueryPerformanceCounter(Start);
  try
    MagWmiGetInfoEx('.', 'root\CIMV2', '', '', 'SELECT * FROM Win32_DiskDrive', WmiResults, instances, errstr);
    for I := 1 to instances do begin
      MagWmiGetInfoEx('.', 'root\CIMV2', '', '', 'ASSOCIATORS OF {Win32_DiskDrive.DeviceID=''' + WmiResults[I, 12] + '''} WHERE AssocClass = Win32_DiskDriveToDiskPartition', WmiResults2, instances2, errstr);
      for II := 1 to instances2 do begin
        MagWmiGetInfoEx('.', 'root\CIMV2', '', '', 'ASSOCIATORS OF {Win32_DiskPartition.DeviceID=''' + WmiResults2[II, 11] + '''} WHERE AssocClass = Win32_LogicalDiskToPartition', WmiResults3, instances3, errstr);
        for III := 1 to instances3 do begin
          if CheckType(WmiResults[I, 32]) or (Pos('7', WmiResults[I, 3])>0) then begin
            Write(WmiResults3[III, 4]);
            Write(WmiResults3[III, 39]);
            Writeln;
          end;
        end;
        WmiResults3 := nil;
      end;
      WmiResults2 := nil;
    end;
    WmiResults := nil;
  except
    Writeln;
    Writeln('error: '+errstr);
  end;
  Writeln;
  QueryPerformanceCounter(Stop);
  if (Freq > 0) then
    Writeln('It took ' + FormatFloat('0.#0', (Stop-Start) / Freq) + ' seconds to complete.');
end;

begin
  try
    CoInitialize(nil);
    GetUSBDiskDriveInfo;
    Readln;
    CoUninitialize;
  except
    on E:Exception do begin
      CoUninitialize;
      Writeln(E.Classname, ': ', E.Message);
      Readln;
    end;
  end;
end.

还有一件事！
称这是一个肮脏的黑客或其他什么，但我注释掉MagWmiGetInfoEx的这一部分（magwmi中的第298行），以使其工作：

//        if Pos ('SELECT', Arg) = 1 then
            wmiObjectSet := wmiServices.ExecQuery (Arg, 'WQL', wbemFlagReturnImmediately, nil)
//        else
//            wmiObjectSet := wmiServices.InstancesOf (Arg, wbemFlagReturnImmediately or
//                                                             wbemQueryFlagShallow, nil)
;

Answer 1

我建议坚持使用WMI。有一个很好的delphi wrapper可用，包括完整的来源，以帮助您入门。

让您入门的查询是“SELECT * FROM WIN32_DiskDrive”，它将返回系统中所有磁盘驱动器的所有信息。对于任何USB驱动器，PNPDeviceID字段应以USBSTOR开头。 MSDN网站是一个很好的资源，用于返回哪些字段。只需将对象翻译成查询。

如果你要从一个线程调用它，你可能需要在进行任何调用之前添加初始化COM（ComInitialize）。在销毁线程之前，请调用ComUnitialialize。

Answer 2

你可以测试这个包; SourceForge中的GLibWMI Components Library。它是与WMI一起工作的包装器。包括可以帮助您的CDiskDriveInfo，CDiskPartitionInfo，CUSBControllerInfo等组件。

此外，还包括所有代码。你可以评估它。

问候。

WMI：如何区分内部“本地磁盘”HDD和外部“本地磁盘”HDD

2 个答案: