Question

我是XSLT，XSL和XML操作技术的新手。现在我对这个示例XML进行一些简单的转换：

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="main.xsl"?>
<content base-url="../../../">
    <article title="TITLE_HERE" timestamp="TIME_HERE">
        <p>SOME TEXT HERE <a href="URL.xml">LINKTEXT</a>.</p>
    </article>
</content>

应用此'main.xsl'转换：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns="http://www.w3.org/1999/xhtml">

<xsl:output method="xml"
            version="1.0"
            encoding="UTF-8"
            doctype-system="http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd"
            doctype-public="-//W3C//DTD XHTML 1.1//EN"
            indent="yes"/>

<xsl:strip-space elements="*"/>

<xsl:param  name="base"
            select="/content/@base-url"/>

<!-- PAGE TEMPLATE -->
<xsl:template match="/content">
    <html lang="en">
        <head>
           ...
        </head>
        <body>
            <div class="content">
                <xsl:apply-templates match="article"/>
            </div>
        </body>
    </html>
</xsl:template>

<!-- ARTICLE NODE TEMPLATE -->
<xsl:template match="article">
    <h2>
        <xsl:value-of select="@title"/>
    </h2>
    <h3>
        <xsl:value-of select="@timestamp"/>
    </h3>
    <xsl:copy-of select="."/>
</xsl:template>

</xsl:stylesheet>

如您所见，使用了copy-of。问题在于锚链接。使用copy-of时，我不能使用concat函数，就像在模板中使用一样：

<xsl:template match="a">
    <a href="{concat($base, @href)}">
        <xsl:value-of select="."/>
    </a>
</xsl:template>

因此，基本上，需要使用一些递归来输出整个节点（标签和属性）但没有子节点（文本和其他节点），使用指定的模板递归解析它们。

如何做到这一点？

Answer 1

您可以使用以下XSLT：匹配“node（）| @ *”的新模板按原样复制节点和属性。而不是副本 - 我使用了apply-templates：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
            xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
            xmlns="http://www.w3.org/1999/xhtml">

<xsl:output method="xml"
        version="1.0"
        encoding="UTF-8"
        doctype-system="http://www.w3.org/TR/xhtml11/DTD/xhtml11.dtd"
        doctype-public="-//W3C//DTD XHTML 1.1//EN"
        indent="yes"/>

<xsl:strip-space elements="*"/>

<xsl:param  name="base"
        select="/content/@base-url"/>

<!-- PAGE TEMPLATE -->
<xsl:template match="/content">
    <html lang="en">
        <head>
       ...
        </head>
        <body>
            <div class="content">
                <xsl:apply-templates select="article"/>
            </div>
        </body>
    </html>
</xsl:template>

<xsl:template match="a">
    <a href="{concat($base, @href)}">
        <xsl:value-of select="."/>
    </a>
</xsl:template>

<!-- ARTICLE NODE TEMPLATE -->
<xsl:template match="article">
    <h2>
        <xsl:value-of select="@title"/>
    </h2>
    <h3>
        <xsl:value-of select="@timestamp"/>
    </h3>
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>

</xsl:stylesheet>

使用模板设备的XSLT递归传递输出

1 个答案: