Question

我正在编写一个proc来在输出文件中创建一个标题。

目前需要采用可选参数，这是标题的可能注释。

我最终将此编码为单个可选参数

proc dump_header { test description {comment = ""}}

但想知道如何使用args实现相同的目标

proc dump_header { test description args }

检查args是否是一个空白参数（$ args ==“”）非常容易，但是如果传递多个参数则不能很好地应对 - 而且我还是需要进行否定检查。

Answer 1

您的proc定义不正确（您会收到错误消息too many fields in argument specifier "comment = """）。应该是：

proc dump_header { test description {comment ""}} {
    puts $comment
}

如果您想使用args，可以检查llength：

proc dump_header {test desc args} {
    switch -exact [llength $args] {
        0 {puts "no comment"}
        1 {puts "the comment is: $args"}
        default {
            puts "the comment is: [lindex $args 0]"
            puts "the other args are: [lrange $args 1 end]"
        }
    }
}

您可能还想在列表中传递名称 - 值对：

proc dump_header {test desc options} {
    # following will error if $options is an odd-length list
    array set opts $options

    if {[info exists opts(comment)]} {
        puts "the comment is: $opts(comment)"
    }
    puts "here are all the options given:"
    parray opts
}
dump_header "test" "description" {comment "a comment" arg1 foo arg2 bar}

有些人更喜欢args和名字 - 值对（a la Tk）的组合

proc dump_header {test desc args} {
    # following will error if $args is an odd-length list
    array set opts $args
    if {[info exists opts(-comment)]} {
        puts "the comment is: $opts(-comment)"
    }
    parray opts
}
dump_header "test" "description" -comment "a comment" -arg1 foo -arg2 bar

Answer 2

我使用tcllib的cmdline库来进行选项解析。

这是cmdline文档中的示例：

set options {
    {a          "set the atime only"}
    {m          "set the mtime only"}
    {c          "do not create non-existent files"}
    {r.arg  ""  "use time from ref_file"}
    {t.arg  -1  "use specified time"}
}
set usage ": MyCommandName \[options] filename ...\noptions:"
array set params [::cmdline::getoptions argv $options $usage]

if {  $params(a) } { set set_atime "true" }
set has_t [expr {$params(t) != -1}]
set has_r [expr {[string length $params(r)] > 0}]
if {$has_t && $has_r} {
    return -code error "Cannot specify both -r and -t"
} elseif {$has_t} {
    ...
}

因此，在您的情况下，您只需使用args代替上述示例中的argv。

Answer 3

应该明确提到args是Tcl中的一个特殊单词，当在参数列表的末尾使用时，它包含所有剩余参数的列表。如果没有给出args，则不会产生错误（与任何其他变量名称不同，这将被视为必需参数）。

我一直在寻找一种方法来实现类似于python的kwargs（可选的键值对参数）的功能，而且效果很好的是（类似于Glenn的最后一个例子）：

proc my_proc {positional_required1 {positional_optional1 "a_string"} args} {
    # Two optional arguments can be given: "opt1" and "opt2"
    if {![string equal $args ""]} {
        # If one or more args is given, parse them or assign defaults.
        array set opts $args
        if {[info exists opts(opt1)]} { set opt1 $opts(opt1) } else { set opt1 0 } 
        if {[info exists opts(op2)]} { set opt2 $opts(opt2) } else { set opt2 -1 }
    } else {
        # If no args are given, assign default values. 
        set op1 0
        set op2 -1
    }   
    # DO STUFF HERE
}

可以这样称呼：

my_proc "positional_required1_argument" 
# OR
my_proc "positional_required1_argument" "a_string"
# OR
my_proc "positional_required1_argument" "a_string" opt1 7
# OR
my_proc "positional_required1_argument" "a_string" opt1 7 opt2 50
# etc.

潜在的缺点（正如我目前所实现的那样）是，如果用户通过了未经批准的键值选项，则没有错误。

如何安全地处理可选参数

3 个答案: