Question

我想知道是否可以用逗号分隔项目列表（在我的情况下，这些将是成绩），并将最后一个项目分隔为＆＃39;和＆＃39;代替。

E.g。 Maths:A (GCSE), English:B (GCSE) and Science:A (GCSE)

我目前的输出如下： Maths:A (GCSE)English:B (GCSE)Science:A (GCSE)

我认为我的代码存在的问题是，在使用position()函数时，它并没有采用正确的节点位置（尽管我可能错了！）

XML代码：

<assignment>
    <education>
        <qualifications>
                <qual>Maths</qual>      <grade>A</grade>    <level>GCSE</level>
                <qual>English</qual>    <grade>B</grade>    <level>GCSE</level>
                <qual>Science</qual>    <grade>A</grade>    <level>GCSE</level>
            </qualifications>
    </education>
</assignment>

XSLT代码：

<xsl:apply-templates select="education">
    <xsl:if test="position() != last()">
        <xsl:text>, </xsl:text>
    </xsl:if>
</xsl:apply-templates>

这显然不会通过使用＆＃39;和＆＃39;来分离最后两个元素。我无法找到任何有助于实现这一目标的东西。

Answer 1

节点教育始终是最后一个节点（它是唯一的节点;-)）

你正在寻找最后一个＆＃39; qual＆＃39;元件

<xsl:apply-templates select="education">

应该是

<xsl:apply-templates select="qual">

希望有所帮助

Answer 2

使用XSLT 1.0，我会匹配每个qual，然后输出第一个grade和level兄弟。

您可以测试前/后qual兄弟姐妹来确定分隔符。

示例...

XSLT 1.0

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="qual">
        <xsl:choose>
            <xsl:when test="preceding-sibling::qual and following-sibling::qual">
                <xsl:text>, </xsl:text>
            </xsl:when>
            <xsl:when test="preceding-sibling::qual">
                <xsl:text> and </xsl:text>
            </xsl:when>
        </xsl:choose>
        <xsl:value-of select="concat(.,':',
            following-sibling::grade[1],
            concat(' (',following-sibling::level,')'))"/>
    </xsl:template>

    <xsl:template match="text()"/>

</xsl:stylesheet>

<强>输出

Maths:A (GCSE), English:B (GCSE) and Science:A (GCSE)

如果您使用的是XSLT 2.0，我会使用xsl:for-each-group和单独的模板来覆盖grade和level。

示例...（生成与XSLT 1.0版本相同的输出）

XSLT 2.0

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="qualifications">
        <xsl:for-each-group select="*" group-starting-with="qual">
            <xsl:choose>
                <xsl:when test="not(position()=1) and not(position()=last())">
                    <xsl:text>, </xsl:text>
                </xsl:when>
                <xsl:when test="position()=last()">
                    <xsl:text> and </xsl:text>
                </xsl:when>
            </xsl:choose>
            <xsl:apply-templates select="current-group()"/>
        </xsl:for-each-group>
    </xsl:template>

    <xsl:template match="qual">
        <xsl:value-of select="concat(.,':')"/>
    </xsl:template>

    <xsl:template match="level">
        <xsl:value-of select="concat(' (',.,')')"/>
    </xsl:template>

</xsl:stylesheet>

Answer 3

<xsl:output method="text"/>
<xsl:strip-space elements="*"/>

<xsl:template match="qual[last()]">
    <xsl:text> and </xsl:text><xsl:value-of select="." />
</xsl:template>

<xsl:template match="qual[1]">
    <xsl:value-of select="." />
</xsl:template>

<xsl:template match="qual">
    <xsl:text>, </xsl:text>
    <xsl:value-of select="." />
</xsl:template>

<xsl:template match="grade">
    <xsl:text>: </xsl:text><xsl:value-of select="." />
</xsl:template>

<xsl:template match="level">
    <xsl:text> (</xsl:text>
    <xsl:value-of select="." />
    <xsl:text>)</xsl:text>
</xsl:template>

Answer 4

为什么不简单地说出你想要的东西：

XSLT 1.0

<xsl:template match="/">
<xsl:for-each select="assignment/education/qualifications/qual">
    <xsl:value-of select="."/>
    <xsl:choose>
        <xsl:when test="position()=last() - 1">
            <xsl:text> and </xsl:text>
        </xsl:when>
        <xsl:when test="position()!=last()">
            <xsl:text>, </xsl:text>
        </xsl:when>
    </xsl:choose>
</xsl:for-each>
</xsl:template>

</xsl:stylesheet>

应用于以下输入时：

<assignment>
   <education>
      <qualifications>
         <qual>Maths</qual>
         <grade>A</grade>
         <level>GCSE</level>
         <qual>English</qual>
         <grade>B</grade>
         <level>GCSE</level>
         <qual>Science</qual>
         <grade>A</grade>
         <level>GCSE</level>
      </qualifications>
   </education>
</assignment>

结果是：

Maths, English and Science

添加成绩和等级值是为读者留下的（平凡）练习。

XML用逗号分隔元素列表的XML

4 个答案: