Question

我还有一个关于在Common Lisp中解码JSON的问题。我决定使用ST-JSON作为我的工具。我能够获得包含JSON数据的JSO对象，并使用st-json:getjso访问所有字段。我想编写一个原则上类似于destructuring-bind的宏，它将为以JSON字段命名的变量提供本地绑定（从那以后我开始怀疑这是不是一个好主意，但那是一个不同的问题）。我想出了以下内容：

(defmacro destructure-jso (jso &body body)
  (let (keys values)
    (st-json:mapjso #'(lambda (key value)
            (push key keys)
            (push value values))
            jso)
    `(destructuring-bind ,keys ,values
       ,@body)))

但是当我尝试在JSO对象上使用它时，我得到错误The value PARAMS is not of the expected type STRUCTURE.，其中PARAMS是对象。谁可以给我解释一下这个？

感谢。

Answer 1

显然，您正在使用destructure-jso这样：

(let ((params (st-json:read-json-from-string "{\"foo\":42,\"bar\":\"baz\"}")))
  (destructure-jso params
    (list foo bar)))

然而，作为宏的destructure-jso在宏扩展时被处理，远在JSON甚至被解析之前。 params作为符号传递给您的宏，而不进行评估;即使尝试进行评估，也不会受到约束。

因此，如果您想编写destructure-jso，则需要在宏扩展时使用密钥列表。您可以以正常方式传递列表：

> (defmacro destructure-jso-2 (vars json &body body)
    `(let ,(mapcar #'(lambda (var)
                       (list var `(getjso ,(string-downcase (symbol-name var)) ,json)))
                   vars)
       ,@body))
DESTRUCTURE-JSO-2

> (let ((params (st-json:read-json-from-string "{\"foo\":42,\"bar\":\"baz\"}")))
    (destructure-jso-2 (foo bar)
    params
  (list foo bar)))
(42 "baz")

或者，如果您愿意，可以使用＆＃34;模板＆＃34;用于创建映射的JSON：

> (defmacro destructure-jso-3 (template json &body body)
    (let (bindings)
      (st-json:mapjso #'(lambda (key val)
                          (declare (ignore val))
                          (push (list (intern (string-upcase key)) `(getjso ,key ,json))
                                bindings))
                      (st-json:read-json-from-string template))
      `(let ,bindings
         ,@body)))
DESTRUCTURE-JSO-3

> (let ((params (st-json:read-json-from-string "{\"foo\":42,\"bar\":\"baz\"}")))
    (destructure-jso-3 "{\"foo\":null,\"bar\":null}"
        params
      (list foo bar)))
(42 "baz")

这里，变量绑定来自第一个（模板）JSON，值来自第二个。模板JSON在宏展开时解析，每次执行代码时都会params JSON。

无论这些是否对您有用，我都不知道。

解析ST-JSON JSO对象的宏

1 个答案: