Question

我正在尝试编写一个宏，该宏扩展为带有解构的let形式。我的问题是我希望得到let表单中定义的符号列表，包括通过destruturing获得的符号。

用例

我试图将这种行为分解出来，例如验证：

(let [a (foo bar)
      {x :x,
       y :y,
       {u :u, v: v :as nested-map} :nested} some-map]
  (and x y nested-map u v ; testing truthiness
       (valid-a? a)
       (valid-x? x)
       (valid-y? y)
       (valid-nested? nested-map)
       (valid-u-and-v? u v)
       ))

建议的解决方案

通过某种and-let宏来实现这一目标真是太好了，我可以像这样调用它：

(and-let [a (foo bar)
          {x :x,
           y :y,
           {u :u, v: v :as nested-map} :nested} some-map]
         (valid-a? a)
         (valid-x? x)
         (valid-nested? nested-map)
         (valid-u-and-v? u v))

我缺少什么

但是我错过了一些访问let表单中绑定的符号列表的方法。如果我有list-bound-symbols函数，我可以这样做：

(defmacro and-let
  "Expands to an AND close that previouly checks that the values declared in bindings are truthy, followed by the tests."
  [bindings & tests]
  (let [bound-symbols (list-bound-symbols bindings) ;; what I'm missing
        ]
    `(let ~bindings
       (and 
         ~@bound-symbols
         ~@tests)
     )))

有人知道我怎么做这个吗？

Answer 1

解构由clojure.core/destructure函数处理。它是公开的，所以我们可以自己调用并提取所有本地人的名字，包括那些用于解构的中间结果：

(defmacro and-let [bindings & tests]
  (let [destructured (destructure bindings)]
    `(let ~destructured
       (and ~@(take-nth 2 destructured)
            ~@tests))))

似乎工作：

(let [foo nil]
  (and-let [a 1
            [b c] [2 3]]
    (nil? foo)))
;= true

Answer 2

你可以使用直接处理地图的功能来完成大部分工作。

(defn validate [vm ; validation map
                dm ; data map
                ]
  (and
    (every? identity (map #(% dm) (flatten (keys vm))))
    (every? identity (map (fn [[k vf]]
                            (if (vector? k)
                              (apply vf (map #(% dm) k))
                              (vf (k dm))))
                          vm))))

例如

(validate {:s string?, :n number? :m number? [:m :n] > } {:s "Hello!", :m 5, :n 3})
; true

(validate {:s string?, :n number? :m number? [:m :n] > } {:s "Hello!", :m 5, :n 6})
; false

(validate {:s string?, :n number? :m number? :u \b [:m :n] > } {:s "Hello!", :m 5, :n 6})
; false

您可以预先在地图中添加任何无关的变量a。这将不必要地测试a的真实性。没有伤害吗？

let forms：如何访问宏中的结构化符号？

2 个答案: