Question

我如何在方案中循环此列表？

(define test-document '(
                    ((h e l l o))
                    ((t h i s)(i s)(t e s t))
                    ))

我试过的只展示了第一栏。

Answer 1

car和cdr系列功能是您导航列表的朋友。以下是一些例子。

(define test-document '(
                    ((h e l l o))
                    ((t h i s)(i s)(t e s t))
                    ))

(car test-document)  ;; `((h e l l o))
(caar test-document)  ;; `(h e l l o)
(cadr test-document) ;; `((t h i s) (i s) (t e s t))
(car (cadr test-document) ;; `(t h i s)
(cadr (cadr test-document) ;; `(i s)
(caddr (cadr test-document) ;; `(test )

定义一个函数，该函数将遍历列表并为每个不是列表的项调用函数。

(define (walk-list lst fun)
   (if (not (list? lst))
      (fun lst)
      (if (not (null? lst))
         (begin
            (walk-list (car lst) fun)
            (walk-list (cdr lst) fun)))))

调用它来打印每个项目。

(walk-list test-document print)

Answer 2

您拥有的是列表清单列表：

(define test-document '(((h e l l o)) ((t h i s) (i s) (t e s t))))

要遍历其元素，您必须创建一个循环循环。为此，我们可以使用map和curry，如下所示：

(map (curry map (curry map
        (compose string->symbol string-upcase symbol->string)))
    test-document)

这会产生以下输出：

(((H E L L O)) ((T H I S) (I S) (T E S T)))

如果您的Scheme解释器没有内置的curry函数，那么您可以按如下方式定义：

(define (curry func . args)
    (lambda x (apply func (append args x))))

希望这会有所帮助。

Answer 3

您是否在想这样的事情？

(define (walk-list lst)
  (define (sub-walk lst)
    (if (null? lst)
        '()
        (let ((x (car lst)))
          (if (list? x)
              (cons (sub-walk x) (sub-walk (cdr lst)))
              (apply string-append (map symbol->string lst))))))
  (flatten (sub-walk lst)))

然后

(walk-list test-document)
=> '("hello" "this" "is" "test")

您可以使用常规嫌疑人（map，filter，...）进行处理。

如果您的Scheme没有flatten程序，您可以使用此程序：

(define (flatten lst)
  (reverse
   (let loop ((lst lst) (res null))
     (if (null? lst)
         res
         (let ((c (car lst)))
           (loop (cdr lst) (if (pair? c) (loop c res) (cons c res))))))))

Scheme循环通过列表

3 个答案: