Question

我有几个不同的按钮调用相同的功能，我希望将它们包装在switch语句中，而不是使用一堆其他条件。任何帮助都会很棒!!!

events:
"click .red, .blue, #black, #yellow" : "openOverlay"

openOverlay: (e) ->
  e.preventDefault()
  e.stopPropagation()

target = $(e.currentTarget)

# the view should be opened
view = 
  if target.hasClass 'red' then new App.RedView
  else if target.hasClass 'blue' then new App.BlueView
  else if target.is '#black' then new App.BlackView
  else
    null

# Open the view
App.router.overlays.add view: view if view?

Answer 1

CoffeeScript中有两种形式的switch：

switch expr
    when expr1 then ...
    when expr2 then ...
    ...
    else ...

和

switch
    when expr1 then ...
    when expr2 then ...
    ...
    else ...

第二种形式可能会对您有所帮助：

view = switch
  when target.hasClass 'red' then new App.RedView
  when target.hasClass 'blue' then new App.BlueView
  when target.is '#black' then new App.BlackView
  else null

如果else null是undefined的可接受值，则可以省略view。您还可以将逻辑包装在（显式）函数中：

viewFor = (target) ->
    # There are lots of ways to do this...
    return new App.RedView   if(target.hasClass 'red')
    return new App.BlueView  if(target.hasClass 'blue')
    return new App.BlackView if(target.is '#black')
    null

view = viewFor target

为您的逻辑命名（即将其包装在函数中）通常有助于澄清您的代码。

Answer 2

除the accepted answer中的详细信息外，CoffeeScript中的switch语句还支持,以提供多个匹配结果：

switch someVar
    when val3, val4 then ...
    else ...

或（如果您的陈述有多行）：

switch someVar
    when val3, val4
        ...
    else
        ...

在咖啡脚本中切换案例陈述

2 个答案: