Question

我正在尝试减少CUDA，我真的是一个新手。我目前正在研究NVIDIA的示例代码。

我想我真的不确定如何设置块大小和网格大小，特别是当我的输入数组比单个块大小更大（512 X 512）时。

这是代码。

template <unsigned int blockSize>
__global__ void reduce6(int *g_idata, int *g_odata, unsigned int n)
{
    extern __shared__ int sdata[];
    unsigned int tid = threadIdx.x;
    unsigned int i = blockIdx.x*(blockSize*2) + tid;
    unsigned int gridSize = blockSize*2*gridDim.x;
    sdata[tid] = 0;

    while (i < n) 
    { 
        sdata[tid] += g_idata[i] + g_idata[i+blockSize]; 
        i += gridSize; 
    }

    __syncthreads();

    if (blockSize >= 512) { if (tid < 256) { sdata[tid] += sdata[tid + 256]; } __syncthreads(); }
    if (blockSize >= 256) { if (tid < 128) { sdata[tid] += sdata[tid + 128]; } __syncthreads(); }
    if (blockSize >= 128) { if (tid < 64) { sdata[tid] += sdata[tid + 64]; } __syncthreads(); }

    if (tid < 32) 
    {
        if (blockSize >= 64) sdata[tid] += sdata[tid + 32];
        if (blockSize >= 32) sdata[tid] += sdata[tid + 16];
        if (blockSize >= 16) sdata[tid] += sdata[tid + 8];
        if (blockSize >= 8) sdata[tid] += sdata[tid + 4];
        if (blockSize >= 4) sdata[tid] += sdata[tid + 2];
        if (blockSize >= 2) sdata[tid] += sdata[tid + 1];
    }

    if (tid == 0) g_odata[blockIdx.x] = sdata[0];
}

然而，在我看来g_odata[blockIdx.x]保存了所有块的部分和，并且，如果我想得到最终结果，我需要求和g_odata[blockIdx.x]数组中的所有项。

我想知道：是否有内核可以完成总结？或者我在这里误解了什么？如果有人能用这个来教育我，我真的很感激。非常感谢。

Answer 1

您的理解是正确的。减少表明here最终存在一系列存储在全局存储器中的块和。

要将所有这些块总和加在一起，需要某种形式的全局同步。您必须等到所有块都完成后再将它们的总和相加。此时您有许多选项，其中一些是：

在主内核之后启动一个新内核，将块总和加在一起
在主机上添加块总和
在主内核的末尾使用atomics将块和加在一起
使用threadfence reduction之类的方法在主内核中添加块和。

如果你搜索CUDA标签，你可以找到所有这些的例子，并讨论它们的优缺点。要查看您发布的主内核如何用于完全缩减，请查看parallel reduction sample code。

Answer 2

Robert Crovella已经回答了这个问题，主要是关于理解而不是表现。

然而，对于所有碰到这个问题的人，我只想强调CUB使块减少功能可用。下面，我提供了一个关于如何使用CUB＆＃39; BlockReduce的简单实例。

#include <cub/cub.cuh>
#include <cuda.h>

#include "Utilities.cuh"

#include <iostream>

#define BLOCKSIZE   32

const int N = 1024;

/**************************/
/* BLOCK REDUCTION KERNEL */
/**************************/
__global__ void sum(const float * __restrict__ indata, float * __restrict__ outdata) {

    unsigned int tid = blockIdx.x * blockDim.x + threadIdx.x;

    // --- Specialize BlockReduce for type float. 
    typedef cub::BlockReduce<float, BLOCKSIZE> BlockReduceT; 

    // --- Allocate temporary storage in shared memory 
    __shared__ typename BlockReduceT::TempStorage temp_storage; 

    float result;
    if(tid < N) result = BlockReduceT(temp_storage).Sum(indata[tid]);

    // --- Update block reduction value
    if(threadIdx.x == 0) outdata[blockIdx.x] = result;

    return;  
}

/********/
/* MAIN */
/********/
int main() {

    // --- Allocate host side space for 
    float *h_data       = (float *)malloc(N * sizeof(float));
    float *h_result     = (float *)malloc((N / BLOCKSIZE) * sizeof(float));

    float *d_data;      gpuErrchk(cudaMalloc(&d_data, N * sizeof(float)));
    float *d_result;    gpuErrchk(cudaMalloc(&d_result, (N / BLOCKSIZE) * sizeof(float)));

    for (int i = 0; i < N; i++) h_data[i] = (float)i;

    gpuErrchk(cudaMemcpy(d_data, h_data, N * sizeof(float), cudaMemcpyHostToDevice));

    sum<<<iDivUp(N, BLOCKSIZE), BLOCKSIZE>>>(d_data, d_result);
    gpuErrchk(cudaPeekAtLastError());
    gpuErrchk(cudaDeviceSynchronize());

    gpuErrchk(cudaMemcpy(h_result, d_result, (N / BLOCKSIZE) * sizeof(float), cudaMemcpyDeviceToHost));

    std::cout << "output: ";
    for(int i = 0; i < (N / BLOCKSIZE); i++) std::cout << h_result[i] << " ";
    std::cout << std::endl;

    gpuErrchk(cudaFree(d_data));
    gpuErrchk(cudaFree(d_result));

    return 0;
}

在此示例中，创建了一个长度为N的数组，结果为32个连续元素的总和。所以

result[0] = data[0] + ... + data[31];
result[1] = data[32] + ... + data[63];
....

Answer 3

为了更好地了解这个主题，您可以查看一下NVIDIA的this pdf，它可以用图形方式解释您在代码中使用的所有策略。

减少CUDA

3 个答案: