Question

我有这样的XML：

<items>
  <item>
    <products>
      <product>laptop</product>
      <product>charger</product>
    </products>
  </item>
  <item>
    <products>
      <product>laptop</product>
      <product>headphones</product>  
    </products>  
  </item>
</items>

我希望它输出像

laptop
charger
headphones

我试图使用distinct-values()，但我想我做错了。谁能告诉我如何使用distinct-values()实现这一目标？感谢。

<xsl:template match="/">            
  <xsl:for-each select="//products/product/text()">
    <li>
      <xsl:value-of select="distinct-values(.)"/>
    </li>               
  </xsl:for-each>
</xsl:template>

但它给我这样的输出：

<li>laptop</li>
<li>charger</li>
<li>laptop></li>
<li>headphones</li>

Answer 1

使用key和generate-id()函数获取不同值的 XSLT 1.0 解决方案：

<?xml version="1.0" encoding="UTF-8"?>
  <xsl:stylesheet
   version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" encoding="UTF-8" indent="yes"/>

<xsl:key name="product" match="/items/item/products/product/text()" use="." />

<xsl:template match="/">

  <xsl:for-each select="/items/item/products/product/text()[generate-id()
                                       = generate-id(key('product',.)[1])]">
    <li>
      <xsl:value-of select="."/>
    </li>
  </xsl:for-each>

</xsl:template>

</xsl:stylesheet>

Answer 2

这是我过去使用的 XSLT 1.0 解决方案，我认为它比使用generate-id()函数更简洁（和可读）。

  <xsl:template match="/">           
    <ul> 
      <xsl:for-each select="//products/product[not(.=preceding::*)]">
        <li>
          <xsl:value-of select="."/>
        </li>   
      </xsl:for-each>            
    </ul>
  </xsl:template>

返回：

<ul xmlns="http://www.w3.org/1999/xhtml">
  <li>laptop</li>
  <li>charger</li>
  <li>headphones</li>
</ul>

Answer 3

您不需要“输出（不同值）”，而是“for-each（distinct-values）”：

<xsl:template match="/">              
  <xsl:for-each select="distinct-values(/items/item/products/product/text())">
    <li>
      <xsl:value-of select="."/>
    </li>
  </xsl:for-each>
</xsl:template>

Answer 4

我在使用Sitecore XSL渲染时遇到了这个问题。使用key（）的方法和使用前一轴的方法都执行得非常慢。我最终使用类似于key（）的方法，但不需要使用key（）。它执行得非常快。

<xsl:variable name="prods" select="items/item/products/product" />
<xsl:for-each select="$prods">
  <xsl:if test="generate-id() = generate-id($prods[. = current()][1])">
    <xsl:value-of select="." />
    <br />
  </xsl:if>
</xsl:for-each>

Answer 5

distinct-values(//product/text())

Answer 6

我发现无需使用generate-id()和key()函数就可以使用XSLT 1.0进行所需的操作。

这是Microsoft特定的解决方案（.NET的XslCompiledTransform类，或MSXSLT.exe或Microsoft platfocm COM对象）。

它基于this answer。您可以将已排序的节点集复制到变量（在下面的样式表中为$sorted-products），然后使用ms:node-set函数将其转换为节点集。然后，您可以for-each第二次对排序的节点集进行操作：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0" xmlns:ms="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="ms">

  <xsl:output method="html" indent="yes" />

  <xsl:template match="/">
    <xsl:variable name="sorted-products">
        <xsl:for-each select="//products/product">
            <xsl:sort select="text()" />

            <xsl:copy-of select=".|@*" />
        </xsl:for-each>
    </xsl:variable>

    <xsl:variable name="products" select="ms:node-set($sorted-products)/product" />

    <xsl:for-each select="$products">
      <xsl:variable name='previous-position' select="position()-1" />

      <xsl:if test="normalize-space($products[$previous-position]) != normalize-space(./text())">
        <li>
          <xsl:value-of select="./text()" />
        </li>
      </xsl:if>
    </xsl:for-each>
  </xsl:template>

</xsl:stylesheet>

输出：

<li>charger</li>
<li>headphones</li>
<li>laptop</li>

您可以尝试in online playground。

如何使用XSLT创建不同的值

6 个答案: