Question

我之前在此门户网站上发布了this question，我得到了满意的解决方案。现在我的问题已经发生了一些变化。如果链接问题中的XML已更新，以便我的号码与其关联的单元如cm，m，in，px等，该怎么办？ XML是：

<root>
<a>
    <b>12cm</b>
    <e>hello</e>
</a> 
<a>
    <b>11m</b>
    <e>how</e>
</a>
<a>
    <c>13m</c>
    <f>are</f>
</a>
<a>
    <b>21cm</b>
    <f>you</f>
</a>
<a>
    <d>22cm</d>
    <e>hello</e>
</a>
<a>
    <c>14m</c>
    <f>hi</f>
</a>

现在我首先需要在我们对它们进行排序并找到最大数量之前，将这些数字转换为类似的单位（比如在cm中）。我怎么能这样做？

我使用以下XSL来解决之前的问题，但现在我需要对其进行更新，以便在排序之前能够转换我的数字。

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:output indent="yes" omit-xml-declaration="yes"/>

<xsl:template match="root">
    <xsl:for-each select="a/b | a/c | a/d">
        <xsl:sort select="." order="descending"/>   <!-- find the unit and transform it in centimeters before sorting -->
        <xsl:if test="position() = 1">
            <highest><xsl:copy-of select="."/></highest>
        </xsl:if>
    </xsl:for-each>
</xsl:template>

</xsl:stylesheet>

注意：我正在使用XSLT 1.0

Answer 1

你喜欢疯狂复杂的表情吗？举个例子，假设你只有单位＆＃34; m＆＃34;，＆＃34; cm＆＃34;和＆＃34; mm＆＃34;考虑一下，你可以写这样的排序表达式......

<xsl:sort select="number(translate(., 'cm', '')) * 
                  (
                     (translate(., '1234567890', '') = 'mm') * 1 + 
                     (translate(., '1234567890', '') = 'cm') * 10 + 
                     (translate(., '1234567890', '') = 'm') * 1000
                  )" 
          order="descending"/>

这利用了数值表达式中的事实，true被评估为1，false被评估为0.在这种特殊情况下，它将所有内容转换为毫米以进行排序。

这避免了必须使用节点集，但这可能是你唯一能说的有利于它......

Answer 2

我已经在这里调整了Dimitre Novatchev的答案（xslt sort output xml）。

如果您将以下样式表应用于输入：

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:ext="http://exslt.org/common"
    exclude-result-prefixes="ext">

    <xsl:output indent="yes" omit-xml-declaration="yes"/>

    <xsl:variable name="letters" select="'abcdefghijklmnopqrstuvwxyz'"/>

    <xsl:template match="/">
        <xsl:variable name="unsorted">
            <root>
                <xsl:for-each select="root/a/*">
                    <xsl:choose>
                        <xsl:when test="string(number(translate(., $letters, '')))!='NaN' and translate(current(), '0123456789', '') = 'cm'">
                            <xsl:element name="{local-name()}">
                                <xsl:attribute name="oldvalue"><xsl:value-of select="."/></xsl:attribute>
                                <xsl:value-of select="number(translate(., $letters, ''))"/>
                            </xsl:element>
                        </xsl:when>
                        <xsl:when test="string(number(translate(., $letters, '')))!='NaN' and translate(current(), '0123456789', '') = 'm'">
                            <xsl:element name="{local-name()}">
                                <xsl:attribute name="oldvalue"><xsl:value-of select="."/></xsl:attribute>
                                <xsl:value-of select="number(translate(., $letters, '')*100)"/>
                            </xsl:element>
                        </xsl:when>
                        <xsl:when test="string(number(translate(., $letters, '')))!='NaN' and translate(current(), '0123456789', '') = 'in'">
                            <xsl:element name="{local-name()}">
                                <xsl:attribute name="oldvalue"><xsl:value-of select="."/></xsl:attribute>
                                <xsl:value-of select="number(translate(., $letters, '')*2.54)"/>
                            </xsl:element>
                        </xsl:when>
                        <xsl:when test="string(number(translate(., $letters, '')))!='NaN' and translate(current(), '0123456789', '') = 'px'">
                            <xsl:attribute name="oldvalue"><xsl:value-of select="."/></xsl:attribute>
                            <xsl:element name="{local-name()}">
                                <xsl:value-of select="number(translate(., $letters, '') div 37.795275591)"/>
                            </xsl:element>
                        </xsl:when>
                    </xsl:choose>
                </xsl:for-each>
            </root>
        </xsl:variable>

        <xsl:variable name="vPass1" select="ext:node-set($unsorted)"/>

        <xsl:apply-templates select="$vPass1/*"/>
    </xsl:template>

    <xsl:template match="root">
        <root>
            <xsl:for-each select="*">
                <xsl:sort select="." data-type="number" order="descending"/>
                <xsl:if test="position() = 1">
                    <highest><xsl:copy-of select="."/></highest>
                </xsl:if>
            </xsl:for-each>
        </root>
    </xsl:template>

</xsl:stylesheet>

输出：

<root>
    <highest>
       <c oldvalue="14m">1400</c>
    </highest>
</root>

如何在排序之前处理值？

2 个答案: