Question

我有两段代码试图将浮点列表转换为Vector3或Vector2列表。这个想法是从列表中一次取2/3个元素并将它们组合成一个向量。最终结果是一系列向量。

    let rec vec3Seq floatList =
        seq {
            match floatList with
            | x::y::z::tail -> yield Vector3(x,y,z)
                               yield! vec3Seq tail
            | [] -> ()
            | _ -> failwith "float array not multiple of 3?"
            }

    let rec vec2Seq floatList =
        seq {
            match floatList with
            | x::y::tail -> yield Vector2(x,y)
                            yield! vec2Seq tail
            | [] -> ()
            | _ -> failwith "float array not multiple of 2?"
            }

代码看起来很相似，但似乎无法提取公共部分。有什么想法吗？

Answer 1

这是一种方法。我不确定这是多么简单，但它确实抽出了一些重复的逻辑。

let rec mkSeq (|P|_|) x =
  seq {
    match x with
    | P(p,tail) -> 
        yield p
        yield! mkSeq (|P|_|) tail
    | [] -> ()
    | _ -> failwith "List length mismatch" }

let vec3Seq =
  mkSeq (function
  | x::y::z::tail -> Some(Vector3(x,y,z), tail)
  | _ -> None)

Answer 2

正如Rex评论的那样，如果你只想要这两种情况，那么如果保留代码，你可能不会有任何问题。但是，如果要提取公共模式，则可以编写一个将列表拆分为指定长度（2或3或任何其他数字）的子列表的函数。完成后，您只需使用map将指定长度的每个列表转换为Vector。

分割列表的功能在F＃库中不可用（据我所知），所以你必须自己实现它。它大致可以这样做：

let divideList n list = 
  // 'acc' - accumulates the resulting sub-lists (reversed order)
  // 'tmp' - stores values of the current sub-list (reversed order)
  // 'c'   - the length of 'tmp' so far
  // 'list' - the remaining elements to process
  let rec divideListAux acc tmp c list = 
    match list with
    | x::xs when c = n - 1 -> 
      // we're adding last element to 'tmp', 
      // so we reverse it and add it to accumulator
      divideListAux ((List.rev (x::tmp))::acc) [] 0 xs
    | x::xs ->
      // add one more value to 'tmp'
      divideListAux acc (x::tmp) (c+1) xs
    | [] when c = 0 ->  List.rev acc // no more elements and empty 'tmp'
    | _ -> failwithf "not multiple of %d" n // non-empty 'tmp'
  divideListAux [] [] 0 list

现在，您可以使用此功能实现两次转换：

seq { for [x; y] in floatList |> divideList 2 -> Vector2(x,y) }
seq { for [x; y; z] in floatList |> divideList 3 -> Vector3(x,y,z) }

这会发出警告，因为我们使用的是一个不完整的模式，它希望返回的列表的长度分别为2或3，但这是正确的期望，所以代码可以正常工作。我也使用序列表达式的简短版本，->与do yield做同样的事情，但它只能在像这样的简单情况下使用。

Answer 3

这与kvb的解决方案类似，但不使用部分活动模式。

let rec listToSeq convert (list:list<_>) =
    seq {
        if not(List.isEmpty list) then
            let list, vec = convert list
            yield vec
            yield! listToSeq convert list
        }

let vec2Seq = listToSeq (function
    | x::y::tail -> tail, Vector2(x,y)
    | _ -> failwith "float array not multiple of 2?")

let vec3Seq = listToSeq (function
    | x::y::z::tail -> tail, Vector3(x,y,z)
    | _ -> failwith "float array not multiple of 3?")

Answer 4

老实说，你拥有的东西非常好，尽管你可以用这个来做一点紧凑：

// take 3 [1 .. 5] returns ([1; 2; 3], [4; 5])
let rec take count l =
    match count, l with
    | 0, xs -> [], xs
    | n, x::xs -> let res, xs' = take (count - 1) xs in x::res, xs'
    | n, [] -> failwith "Index out of range"

// split 3 [1 .. 6] returns [[1;2;3]; [4;5;6]]
let rec split count l =
    seq { match take count l with
          | xs, ys -> yield xs; if ys <> [] then yield! split count ys }

let vec3Seq l = split 3 l |> Seq.map (fun [x;y;z] -> Vector3(x, y, z))
let vec2Seq l = split 2 l |> Seq.map (fun [x;y] -> Vector2(x, y))

现在，拆分列表的过程已移至其自己的通用“拍摄”和“拆分”功能中，更容易将其映射到您想要的类型。

避免F＃中的代码重复

4 个答案: