这个内存泄漏的来源是什么（使用TCollection时）

Question

我有一些我没写过的代码，但是有内存泄漏。真正奇怪的是，如果在返回结构之前将结构归零，则内存只会泄漏。

可重现的最小代码

泄漏在Delphi 5和Delphi 7中是可重现的。

首先我们有一个结构：

type
   TLocalFile = packed record
      FileName: AnsiString;
   end;

此结构是CollectionItem对象的私有成员：

TEntry = class(TCollectionItem)
private
   FLocalFile: TLocalFile;
end;

然后我们拥有拥有的集合，它有一个可以返回填充结构的函数：

TEntries = class(TCollection)
protected
    function GetLocalFile: TLocalFile;
public
    procedure DoStuff;
end;

奇怪的是GetLocalFile函数：

function TEntries.GetLocalFile: TLocalFile;
var
    s: AnsiString;
begin
    //Only leaks if i initialize the returned structure
//  FillChar(Result, SizeOf(Result), 0);
    ZeroMemory(@Result, SizeOf(Result));

    s := 'Testing Leak';
    Result.Filename := s; //'Testing leak';  only leaks if i set the string through a variable
end;

实际上，这个函数传递给一个流，并返回一个填充的结构，但现在这并不重要。

接下来我们有一个集合方法，它将填充所有条目的LocalFile结构：

procedure TEntries.DoStuff;
var
    x: Integer;
begin
    for X := 0 to Count-1 do
    begin
       (Items[X] as TEntry).FLocalFile := GetLocalFile;
    end;
end;

最后，我们构建一个集合，向其中添加10个项目，让它们DoStuff，然后释放列表：

procedure TForm1.Button1Click(Sender: TObject);
var
    list: TEntries;
    i: Integer;
    entry: TCollectionItem;
begin
    list := TEntries.Create(TEntry);
    try
        for i := 1 to 10 do
            entry := list.Add;

        list.DoStuff;
    finally
        list.Free;
    end;
end;

我们创建了 10 项目，我们泄漏 9 AnsiStrings。

令人恐惧的令人困惑的事情

此代码有一些方法不会泄漏。它只在使用中间字符串堆栈变量

时泄漏

变化：

function TEntries.GetLocalFile: TLocalFile;
var
   s: AnsiString;
begin
   s := 'Testing Leak';
   Result.Filename := s; //'Testing leak';  only leaks if i set the string through a variable
end;

到

function TEntries.GetLocalFile: TLocalFile;
begin
   Result.Filename := 'Testing leak'; //doesn't leak
end;

并且它不会泄漏。

另一种方法 不 在返回结构之前初始化结构：

移除对FillChar或ZeroMemory的调用，但不会泄漏：

function TEntries.GetLocalFile: TLocalFile;
var
    s: AnsiString;
begin
    //Only leaks if i initialize the returned structure
//  FillChar(Result, SizeOf(Result), 0);
//  ZeroMemory(@Result, SizeOf(Result));

    s := 'Testing Leak';
    Result.Filename := s; //'Testing leak';  only leaks if i set the string through a variable
end;

这些是奇怪的决议。无论我是否使用中间堆栈变量，无论是否将结构归零，都不应对内存清理产生任何影响。

我怀疑这是编译器中的错误。这意味着我（意思是写这篇文章的人）正在做一些根本错误的事情。我认为它与TCollectionItemClass有关。但我不能为我的生活弄清楚是什么。

完整代码

unit FMain;

interface

uses
  Windows, Messages, SysUtils, Variants, Classes, Graphics, Controls, Forms,
  Dialogs, StdCtrls;

type
    TLocalFile = packed record
        FileName: AnsiString;
    end;

    TEntry = class(TCollectionItem)
   private
        FLocalFile: TLocalFile;
    end;

    TEntries = class(TCollection)
    protected
        function GetLocalFile: TLocalFile;
    public
        procedure DoStuff;
    end;

  TForm1 = class(TForm)
    Button1: TButton;
    procedure Button1Click(Sender: TObject);
  private
  public
  end;


var
  Form1: TForm1;

implementation

{$R *.dfm}

uses
    contnrs;

procedure TForm1.Button1Click(Sender: TObject);
var
    list: TEntries;
    i: Integer;
    entry: TCollectionItem;
begin
    list := TEntries.Create(TEntry);
    try
        for i := 1 to 10 do
        begin
            entry := list.Add;
        end;

        list.DoStuff;
    finally
        list.Free;
    end;
end;

{ TEntries }

procedure TEntries.DoStuff;
var
    x: Integer;
    entry: TEntry;
begin
    for X := 0 to Count-1 do
    begin
        entry := Items[X] as TEntry;
        entry.FLocalFile := GetLocalFile;
   end;
end;

function TEntries.GetLocalFile: TLocalFile;
var
    s: AnsiString;
begin
    //Only leaks if i initialize the returned structure
//  FillChar(Result, SizeOf(Result), 0);
    ZeroMemory(@Result, SizeOf(Result));

    s := 'Testing Leak';
    Result.Filename := s; //'Testing leak';  only leaks if i set the string through a variable
end;

end.

哦，不要忘记将FastMM4添加到您的项目中（如果您还没有内置），这样您就可以检测到泄漏。

Answer 1

AnsiString（及其Unicode对应项）由编译器引用计数。你不能简单地将包含引用的内存归零;您需要为其分配''，以便编译器生成代码以减少引用计数并正确释放内存。

尝试阻止清除包含对动态数组，接口或（某些）变体的引用的数据结构时，您会遇到类似的问题。

如果您没有使用最近足以支持Default编译器魔术表达式的Delphi版本（我相信它是在D2009中引入的），那么安全清除记录的最佳方法是调用{ {1}}首先，然后将内存归零。