Question

如何在SQL中为变量分配exec调用的结果？我有一个名为up_GetBusinessDay的存储过程，它返回一个日期。

你能做这样的事吗：

exec @PreviousBusinessDay = dbo.up_GetBusinessDay @Date, -1

Answer 1

我总是使用返回值来传递错误状态。如果你需要传回一个值，我会使用输出参数。

示例存储过程，带有OUTPUT参数：

CREATE PROCEDURE YourStoredProcedure 
(
    @Param1    int
   ,@Param2    varchar(5)
   ,@Param3    datetime OUTPUT
)
AS
IF ISNULL(@Param1,0)>5
BEGIN
    SET @Param3=GETDATE()
END
ELSE
BEGIN
    SET @Param3='1/1/2010'
END
RETURN 0
GO

使用OUTPUT参数调用存储过程：

DECLARE @OutputParameter  datetime
       ,@ReturnValue      int

EXEC @ReturnValue=YourStoredProcedure 1,null, @OutputParameter OUTPUT
PRINT @ReturnValue
PRINT CONVERT(char(23),@OutputParameter ,121)

输出：

0
2010-01-01 00:00:00.000

Answer 2

如果您只想返回一个整数，这将有效：

DECLARE @ResultForPos INT 
EXEC @ResultForPos = storedprocedureName 'InputParameter'
SELECT @ResultForPos

Answer 3

declare @EventId int

CREATE TABLE #EventId (EventId int)

insert into #EventId exec rptInputEventId

set @EventId = (select * from #EventId)

drop table #EventId

Answer 4

从documentation（假设您使用SQL-Server）：

USE AdventureWorks;
GO
DECLARE @returnstatus nvarchar(15);
SET @returnstatus = NULL;
EXEC @returnstatus = dbo.ufnGetSalesOrderStatusText @Status = 2;
PRINT @returnstatus;
GO

所以是的，它应该那样工作。

Answer 5

我有同样的问题。尽管这里有很好的答案，但我还是决定创建一个表值函数。使用表（或标量）值函数，您不必更改存储的过程。我只是从表值函数中进行了选择。请注意，参数（MyParameter是可选的）。

CREATE FUNCTION [dbo].[MyDateFunction] 
(@MyParameter varchar(max))
RETURNS TABLE 
AS
RETURN 
(
    --- Query your table or view or whatever and select the results.
    SELECT DateValue FROM MyTable WHERE ID = @MyParameter;
)

要分配给变量，您只需执行以下操作即可：

Declare @MyDate datetime;
SET @MyDate = (SELECT DateValue FROM MyDateFunction(@MyParameter));

您还可以使用标量值函数：

CREATE FUNCTION TestDateFunction()  
RETURNS datetime  
BEGIN  
    RETURN (SELECT GetDate());
END

那你就可以做

Declare @MyDate datetime;
SET @MyDate = (Select dbo.TestDateFunction());
SELECT @MyDate;

Answer 6

这是动态查询的解决方案。

例如，如果您有更多具有不同后缀的表：

dbo.SOMETHINGTABLE_ONE, dbo.SOMETHINGTABLE_TWO

代码：

DECLARE @INDEX AS NVARCHAR(20)
DECLARE @CheckVALUE AS NVARCHAR(max) = 'SELECT COUNT(SOMETHING) FROM 
dbo.SOMETHINGTABLE_'+@INDEX+''
DECLARE @tempTable Table (TempVALUE int)
DECLARE @RESULTVAL INT

INSERT INTO @tempTable
    EXEC sp_executesql @CheckVALUE

SET @RESULTVAL = (SELECT * FROM @tempTable)

DELETE @tempTable

SELECT @RESULTVAL

如何将exec结果分配给sql变量？

6 个答案: