Question

我想将epsilon下面的绝对值截断为0，例如

Truncate[{-3, -2, -1, 0, 1, 2, 3}, 1.5] -> {-3, -2, 0, 0, 0, 2, 3}

我想我可以使用Scan []和If []编写一个函数，但是在Mathematica中是否有更惯用的“单行”方式？

Answer 1

许多选项都有效：

Map[If[Abs[#] < 1.5, 0, #] &, {-3, -2, -1, 0, 1, 2, 3}]

或同等的：

If[Abs[#] < 1.5, 0, #] & /@ {-3, -2, -1, 0, 1, 2, 3}

或者，如果您愿意：

ReplaceAll[{-3, -2, -1, 0, 1, 2, 3}, (x_ /; Abs[x] < 1.5) -> 0]

相当于：

{-3, -2, -1, 0, 1, 2, 3} /. (x_ /; Abs[x] < 1.5) -> 0

或

ReplaceAll[{-3, -2, -1, 0, 1, 2, 3}, (x_?(Abs[#] < 1.5 &)) -> 0]

相当于：

{-3, -2, -1, 0, 1, 2, 3} /. (x_?(Abs[#] < 1.5 &)) -> 0

Answer 2

内置函数Chop几乎就是您正在寻找的内容（它可以在列表中运行，如您的示例所示）。一个潜在的惊喜是它不会切断（截断）整数，只有浮点数。因此，为了使您的示例按预期工作，首先使用N函数将列表转换为浮点数：

Chop[N@{-3, -2, -1, 0, 1, 2, 3}, 1.5] -> {-3., -2., 0, 0, 0, 2., 3.}

正如Ramashalanka所说，为了更普遍地做这类事，我建议：

If[Abs[#]<1.5&, 0, #]& /@ {-3, -2, -1, 0, 1, 2, 3}

即，在列表上映射的lambda函数。

Answer 3

这是一种方法（f3），速度快了近一个数量级。

它改编自Fred Simons的代码。

f1 = If[Abs[#] < 1.5, 0, #] & /@ # &;

f2 = # /. (x_ /; Abs[x] < 1.5) -> 0 &;

f3 = # (1 - Unitize@Clip[#, {-1.5, 1.5}, {0, 0}]) &;

lst = RandomInteger[{-100, 100}, 5000];

SameQ @@ (#@lst & /@ {f1, f2, f3})

First@Timing@Do[#@lst, {500}] & /@ {f1, f2, f3}

(* Out=  True                  *)

(* Out=  {0.406, 2.282, 0.047} *)

Mathematica：用于替换符合条件的列表中的值的惯用法？

3 个答案: