Question

我正在为datapower写一个xslt，因为我得到了一个日期（付款日期）。我必须检查该日期（付款日期）是否在当前日期的180天内

我通过以下

获得现在的日期

<xsl:variable name="timestamp" select="date:date-time()"/>

现在如何检查条件180天

以下是我的xslt

<?xml version="1.0" encoding="utf-8"?>

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:dp="http://www.datapower.com/extensions"
    xmlns:date="http://exslt.org/dates-and-times"
    xmlns:dpconfig="http://www.datapower.com/param/config"
    extension-element-prefixes="dp"
    exclude-result-prefixes="dp dpconfig"
>

  <xsl:output method="xml"/>

  <xsl:template match="/">
<PaymentDate><xsl:value-of select="dp:http-request-header('X-payment-date')"/></PaymentDate>  (From request I am getting payment date)

<xsl:variable name="timestamp" select="date:date-time()"/>        (From here I am getting present date)

<xsl:if  (this is what I am confused)

由于

Answer 1

在XSLT 1.0中计算日期差异：

<xsl:stylesheet version="1.0" 
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:date="http://exslt.org/dates-and-times"
extension-element-prefixes="date">

<xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>

<xsl:template match="/">
    <output>
        <difference>
            <xsl:call-template name="date-difference">
                <xsl:with-param name="date1" select="input/originalDate" />
                <xsl:with-param name="date2" select="date:date-time()" />
            </xsl:call-template>
        </difference>
    </output>
</xsl:template> 

<xsl:template name="date-difference">
    <xsl:param name="date1"/>
    <xsl:param name="date2"/>
    <xsl:param name="JDN1">
        <xsl:call-template name="JDN">
            <xsl:with-param name="date" select="$date1" />
        </xsl:call-template>
    </xsl:param>
    <xsl:param name="JDN2">
        <xsl:call-template name="JDN">
            <xsl:with-param name="date" select="$date2" />
        </xsl:call-template>
    </xsl:param>
    <xsl:value-of select="$JDN2 - $JDN1"/>
</xsl:template> 

<xsl:template name="JDN">
    <xsl:param name="date"/>
    <xsl:param name="year" select="substring($date, 1, 4)"/>
    <xsl:param name="month" select="substring($date, 6, 2)"/>
    <xsl:param name="day" select="substring($date, 9, 2)"/>
    <xsl:param name="a" select="floor((14 - $month) div 12)"/>
    <xsl:param name="y" select="$year + 4800 - $a"/>
    <xsl:param name="m" select="$month + 12*$a - 3"/>
    <xsl:value-of select="$day + floor((153*$m + 2) div 5) + 365*$y + floor($y div 4) - floor($y div 100) + floor($y div 400) - 32045" />
</xsl:template> 

</xsl:stylesheet>

当应用于以下输入XML时：

<input>
    <originalDate>2013-09-15</originalDate>
</input>

结果将是：

<?xml version="1.0" encoding="UTF-8"?>
<output>
  <difference>179</difference>
</output>

如果转换今天进行，2014-03-13。

Answer 2

IBM Datapower提供对现有EXSLT功能的扩展。有一个名为'差异'的函数，带有以下签名。

差异（）返回第一个日期和第二个日期之间的持续时间。句法 date：difference（start-dateTime，end-dateTime）

您可以使用此功能查找日期差异。有关数据电源中可用的扩展功能的更多信息，请参见下面的链接。转到第5章并查找用于操作“日期时间”的函数。

http://pic.dhe.ibm.com/infocenter/wsdatap/v3r8m1/topic/xm70/ExtensionFunctions.pdf

-Ajitabh

Answer 3

DataPower支持日期：差异

差异（）

返回第一个日期和第二个日期之间的持续时间。语法

日期：差异（start-dateTime，end-dateTime）

您可以将当前日期作为end-DateTime传递，日期要检查为start-DateTime

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs"
xmlns:date="http://exslt.org/dates-and-times" version="1.0">
<!--<xsl:key name="lang" match="element" use="@language"></xsl:key>-->
<xsl:template match="/">
    <xsl:variable name="date1" select="date:date-time()"/>
    <xsl:variable name="date2" select="'2013-09-15'"/>
    <output>
        <difference>
    <xsl:value-of select="translate(date:difference($date2, $date1),'PD','')"/>
        </difference>
    </output>
</xsl:template>
</xsl:stylesheet>

我们如何在datapower的xslt中测试日期是否在180天之内

3 个答案:

在XSLT 1.0中计算日期差异：