Question

我在Spreadsheet::WriteExcel和使用VLOOKUP的公式方面遇到了困难。以下测试脚本使用一些数据填充工作表，并尝试创建VLOOKUP公式。当我打开生成的Excel文件时，公式结果显示为#VALUE!。如果我手动编辑任何包含公式的单元格（按F2然后只输入ENTER而不更改任何内容），我可以让Excel正确评估公式。知道出了什么问题吗？

对于它的价值，如果我在OpenOffice中打开相同的文件，公式可以正常工作。

use strict;
use warnings;
use Spreadsheet::WriteExcel;

my $wb = Spreadsheet::WriteExcel->new('foo.xls');
my $ws = $wb->add_worksheet;

for my $r (0 .. 9){
    for my $c (0 .. 4){
        $ws->write($r, $c, $r * 10 + $c);
    }
    $ws->write($r, 10, $r * 10);
    my $formula = sprintf('=VLOOKUP(K%s, A1:B10, 2, FALSE)', $r + 1);
    $ws->write( $r, 11, $formula );
    # $ws->write_formula( $r, 11, $formula ); # Does not help either.
}

版本信息：

Excel 2007 SP2。
Spreadsheet :: WriteExcel：尝试了2.25和2.37。

Answer 1

我是Spreadsheet :: WriteExcel的作者。

这是使用公式解析器和WriteExcel中的某些公式类型的已知错误。您可以使用store_formula()和repeat_formula()解决此问题，如下所示：

use strict;
use warnings;
use Spreadsheet::WriteExcel;

my $wb = Spreadsheet::WriteExcel->new('foo.xls');
my $ws = $wb->add_worksheet;

my $formula = $ws->store_formula('=VLOOKUP(K1, A1:B10, 2, FALSE)');

# Workaround for VLOOKUP bug in WriteExcel.
@$formula = map {s/_ref2d/_ref2dV/;$_} @$formula;

for my $r (0 .. 9){
    for my $c (0 .. 4){
        $ws->write($r, $c, $r * 10 + $c);
    }
    $ws->write($r, 10, $r * 10);

    $ws->repeat_formula( $r, 11, $formula, undef, qr/^K1$/, 'K' . ($r +1) );
}

Answer 2

我是writeexcel rubygem的维护者。例如，ruby代码在下面。

require 'rubygems'
require 'writeexcel'

wb = WriteExcel.new('fooruby.xls')
ws = wb.add_worksheet

formula = ws.store_formula('=VLOOKUP(K1, A1:B10, 2, FALSE)')

# Workaround for VLOOKUP bug in WriteExcel.
formula.map! {|f| f.sub(/_ref2d/, '_ref2dV') }

(0..9).each do |row|
  (0..4).each { |col| ws.write(row, col, row * 10 + col) }
  ws.write(row, 10, row * 10)
  ws.repeat_formula(row, 11, formula, nil, /^K1$/, "K#{row+1}" )
end

wb.close

如何让Perl的Spreadsheet :: WriteExcel用VLOOKUP创建公式？

2 个答案: