Question

我是LISP的新手，我目前正在尝试定义一个函数，该函数将传递两个将随机执行的其他形式。因此，例如，如果我要执行任何表单，它将从选择中随机执行其中一个表单以返回结果。

有人会知道这方面的任何例子吗？我似乎对LISP了解不足以形成网络搜索，以便找回我正在寻找的结果。

Answer 1

用宏...

包装功能实现

Barmar's answer显示了如何使用函数执行此操作。我认为对于这个问题，这是最明智的实现技术。 Wojciech Gac's answer建议用宏来做这件事。我认为这是这个问题最自然的编程接口（但是，如评论中所述，该答案中的宏存在一些问题）。最后，我认为值得将这两种技术结合起来，以便您获得实现的好处（如果需要，可以稍后使用函数对象），以及其余时间的便捷界面。

(defun call-one (functions)
  (funcall (nth (random (length functions)) functions)))

(defmacro one-of (&body forms)
  `(call-one (list ,@(mapcar (lambda (form)
                               `(lambda ()
                                  ,form))
                             forms))))

(call-one (list (constantly 3) (constantly 4)))
;=> 4 ; or 3

(one-of 3 4)
;=> 3 ; or 4

在我看来，这种类型的宏实现技术，主要功能是作为一个函数实现的，而宏是根据函数实现的，这在适用时是很好的做法。将功能实现为一个函数通常更容易，因为您对名称捕获，构造表单等的关注较少。有时可以使用功能实现，因此您可以获得更多灵活性。在函数方面实现宏意味着宏实际上是你的语法糖;从概念上讲，您需要做的就是在匿名函数中包装一些单独的表单，这对于宏来说并不是太复杂的任务。当然，这对每个宏都不起作用，但在我看来，当它适用时，它会导致代码更易于维护，并且从一开始就不那么错了。

但是要避免多余的工作......

但这里有一个值得注意的问题。 one-of的扩展会创建一个列表并将其传递给call-one：

(macroexpand-1 '(one-of 3 4))
;=> (CALL-ONE (LIST (LAMBDA () 3) (LAMBDA () 4)))

call-one计算函数列表的长度并生成随机数。对于大多数调用来说，这很好，但它对于one-of的扩展并不好，因为这意味着我们重新计算一次又一次不变的列表的长度。当我们使用one-of时，我们可以在宏展开时计算(length functions)，但我们仍需要一种方法将其提供给call-one。因此，我们可以通过向call-one添加一个默认为(length functions)的可选参数来稍微更改功能接口。在one-of的扩展中，我们只提供一个常数值。

(defun call-one (functions &optional (len (length functions)))
  (funcall (nth (random len) functions)))

(defmacro one-of (&body forms)
  `(call-one (list ,@(mapcar (lambda (form)
                               `(lambda ()
                                  ,form))
                             forms))
             ,(length forms)))

因此我们得到了这种扩展：

(macroexpand-1 '(one-of 3 4))
;=> (CALL-ONE (LIST (LAMBDA () 3) (LAMBDA () 4)) 2)

Answer 2

这需要任意数量的函数，并随机调用其中一个函数：

(defun execute-one (&rest funcs)
  (let* ((random-pos (random (length funcs)))
         (func (nth random-pos funcs)))
    (funcall func)))

(execute-one
  (lambda () (print 3))
  (lambda () (print 5))
  (lambda () (print 10)))

Answer 3

嗯，在Barmar的回答中，提供给execute-one的表单必须是lambda类型，并且是零参数。我建议将其作为宏实现：

(defmacro execute-one (&body funcs)
  `(let* ((random-pos (random (length ',funcs)))
      (func (nth random-pos ',funcs)))
     (eval func)))

现在您可以提供任意形式，execute-one将随机评估其中一种形式。

示例：

(execute-one
  (+ 10 100)
  (* 234 934)
  (expt 2 100))

=> 110

编辑：我已经能够从中驱除eval：

(defmacro execute-one (&body funcs)
  `(let* ((random-pos (random (length ',funcs)))
      (func (nth random-pos ',funcs)))
     (apply #'funcall func)))

@Rainer，除了eval之外，你能详细说明为什么风格不好吗？

如何在LISP中定义一个函数，它传递两个Forms然后随机执行它们

3 个答案:

用宏...

但是要避免多余的工作......