Question

我真的很担心如何在VB.net上创建一个timer.tick事件。

我的计划应如何运作：

实际上，我正在创建一个FCFS算法，我的目标是使用进度条显示甘特图。对此，我希望我的计时器控制给定的进度条。在进度条达到最大值后，计时器将停止，下一个计时器将启动，下一个进度条也将起作用。我真的不知道该怎么做。我是新手。请帮我。：（

这是我的代码：

Private progress As New List(Of ProgressBar)

Private timex As New List(Of Timer)

For cnt4 = 0 To (Val(TextBox1.Text) - 1)

        progress.Add(New ProgressBar)
        With progress(cnt4)
            .Parent = Me
            .Left = 0
            .Height = 23
            .Width = 50
            .Top = .Height * cnt4 + 50
            .Visible = True
            .Tag = cnt4
            .Text = ""
            .Maximum = Val(burstbox(cnt4).Text)
            .Minimum = 0
            .Name = "progress" & cnt4
            .Location = New Point(17 + (.Width * cnt4), 532)

        End With

        timex.Add(New Timer)

        With timex(cnt4)

            .Tag = cnt4
            .Interval = 100
        End With

    Next


End Sub

Answer 1

您可以使用AddHandler方法。

timex.Add(New Timer)
AddHandler timex(cnt4).Tick, AddressOf myTickEvent

然后您将创建您的活动。

Private Sub myTickEvent(sender As Object, e As EventArgs)
    Dim instance As Integer = CInt(DirectCast(sender, Timer).Tag)

    'Do your magic here
End Sub

通过一个有效的例子来充实它：

Public Class Form1
    Private progress As New List(Of ProgressBar)
    Private timex As New List(Of Timer)

    Private Sub Button1_Click(sender As Object, e As EventArgs) Handles Button1.Click

        For cnt4 = 0 To (Val(TextBox1.Text) - 1)

            progress.Add(New ProgressBar)
            With progress(cnt4)
                .Parent = Me
                .Left = 0
                .Height = 23
                .Width = 50
                .Top = .Height * cnt4 + 50
                .Visible = True
                .Tag = cnt4
                .Text = ""
                .Maximum = Val(burstbox(cnt4).Text) 'Set Maximum
                .Minimum = 0
                .Name = "progress" & cnt4
                .Location = New Point(17 + (.Width * cnt4), 532)
                Me.Controls.Add(progress(cnt4)) 'Have to add it to your Containers Control Collection
            End With

            timex.Add(New Timer)
            AddHandler timex(cnt4).Tick, AddressOf myTickEvent

            With timex(cnt4)  
                .Tag = cnt4
                .Interval = 100
            End With
        Next
        timex(0).Start()
    End Sub

    Private Sub myTickEvent(sender As Object, e As EventArgs)
        Dim instance As Integer = CInt(DirectCast(sender, Timer).Tag) 'Get Index of the Active Timer
        If progress(instance).Value >= progress(instance).Maximum Then
            timex(instance).Stop()
            RemoveHandler timex(instance).Tick, AddressOf myTickEvent
            If instance < progress.Count - 1 Then
                timex(instance + 1).Start()
            End If
        Else
            progress(instance).Value += 1
        End If
    End Sub

End Class

如何创建运行时timer.tick事件？

1 个答案: