Question

如何获得作为当前HEAD的第一级后代的分支列表？

我可以通过以下方式获取整棵树的列表：

git log --graph --abbrev-commit --pretty=decorate --branches

给出了

* 2eff4a7... (refs/heads/issue-8351) Added a factory factory factory.
* 2e387aa... Refactored all of the factory factories.
| * b3fad52... (refs/heads/issue-8354) Moved the baz out of the constructor.
|/
| * f4cf3fe... (refs/heads/experimental) quuz looking good
| * 1d276b9... Risky fix to replace the quux with the quuz.
| * d6b0222... (refs/heads/issue-7559) Fixed the quux in the foo.
|/
| * 3f4cfff... (refs/heads/dev) wip
|/
* 76f493f... (refs/heads/master) SVN 30192

但是我想获得当前分支的第一级子级的简单列表，例如master的示例：

dev
issue-7559
issue-8354
issue-8351

如果我在分支issue-7559，我只会看到：

experimental

我怎么能这样做？

Answer 1

你可以这样做。

首先是通常的序言：

#! /usr/bin/perl

use warnings;
use strict;

使用git for-each-ref收集每个参考号的SHA-1和名称：

sub refs {
  open my $fh, "-|", "git", "for-each-ref",
                            "--format=%(objectname)\t%(refname:short)"
    or die "$0: failed to run git for-each-ref";

  my %ref2sha;
  while (<$fh>) {
    chomp;
    my($sha,$ref) = split /\t/;
    $ref2sha{$ref} = $sha;
  }

  \%ref2sha;
}

如果提交是HEAD的子级，则从HEAD可到达的提交集合（不包括从提交中可到达的所有内容）是空集。我们可以使用git rev-list检查此关系。

sub is_child {
  my($ref) = @_;

  # git rev-list ^dev master
  my $refs = `git rev-list ^$ref HEAD -- 2>&1`;
  die "$0: git rev-list-failed.\n$refs" if $?;

  $refs !~ /\S/;
}

对于HEAD的后代但不等同于HEAD的每个引用，我们使用git log检查从HEAD到该引用的路径。如果路径包含另一个分支的提示，则ref不能是第一级子级。

这个挑战的所有幸存者都是一级孩子。

chomp(my $head = `git rev-parse HEAD 2>&1`);
die "$0: git rev-parse failed.\n$head" if $?;

my $ref2sha = refs;
my %headsha = reverse %$ref2sha;

REF:
foreach my $ref (keys %$ref2sha) {
  my $refsha = $ref2sha->{$ref};

  next if $refsha eq $head || !is_child $ref;

  my @log = `git log --pretty=format:%H ..$ref 2>&1`;
  die "$0: git log failed.\n@log" if $?;
  for (@log) {
    chomp;
    next if $_ eq $refsha;
    next REF if exists $headsha{$_};
  }

  print $ref, "\n";
}

使用Git显示所有第一级后代分支

1 个答案: