Question

我继承了一个旧的Web应用程序，即使用经典ASP将表单中收集的数据写入Access 2007数据库。

现在他们需要能够以西里尔字母表收集输入。

我完全不熟悉代码页/字符集，并且使用非拉丁字母表。

我已经尝试将条目页面上的字符集更改为ISO-8859-1，它似乎存储了字符的ascii值（例如：＃1076;）。因此浏览器可以很好地解释和阅读，但在将数据导出到excel以传递给需要它的部门方面几乎没用。

所以我的问题是：

是否有一种简单的方法可以从网络表单中捕获西里尔字符并将其作为西里尔字符插入到我的访问表中？

或者

访问数据库中是否有可以将十进制值（＃1076;）转换为访问本身内的西里尔字符的工具或设置。

Answer 1

如果你坚持使用UTF-8作为你的页面，他们应该工作（但请参阅下面的重要说明）。虽然Access确实不在内部将Unicode字符存储为UTF-8，但Access OLEDB驱动程序将为您处理转换。

考虑以下示例脚本（其中65001是UTF-8的“代码页”）：

<%@ CODEPAGE = 65001 %>
<!DOCTYPE html PUBLIC "-//W3C//DTD XHTML 1.0 Strict//EN" "http://www.w3.org/TR/xhtml1/DTD/xhtml1-strict.dtd">
<html>
<head>
<meta http-equiv="content-type" content="text/html; charset=UTF-8" />
<title>Classic ASP Unicode Test</title>
</head>
<body bgcolor="white" text="black">
<%
Dim con, cmd, rst
Const adVarWChar = 202
Const adParamInput = 1
Set con = CreateObject("ADODB.Connection")
con.Mode = 3  ' adModeReadWrite
con.Open _
        "Provider=Microsoft.Jet.OLEDB.4.0;" & _
        "Data Source=C:\_wwwdata\unicodeTest.mdb;"
If Len(Trim(Request.Form("word"))) > 0 Then
    Set cmd = CreateObject("ADODB.Command")
    cmd.ActiveConnection = con
    cmd.CommandText = "INSERT INTO vocabulary (word, language, english_equiv) VALUES (?,?,?)"
    cmd.Parameters.Append cmd.CreateParameter("?", adVarWChar, adParamInput, 255, Request.Form("word"))
    cmd.Parameters.Append cmd.CreateParameter("?", adVarWChar, adParamInput, 255, Request.Form("language"))
    cmd.Parameters.Append cmd.CreateParameter("?", adVarWChar, adParamInput, 255, Request.Form("english_equiv"))
    cmd.Execute
    Set cmd = Nothing
End If
%>
<h2>Word list:</h2>
<table border=1>
    <tr>
        <th>word</th><th>language</th><th>english_equiv</th>
    </tr>
<%
Set rst = CreateObject("ADODB.Recordset")
rst.Open _
        "SELECT * FROM vocabulary ORDER BY ID", _
        con, 3, 3
Do Until rst.EOF
    Response.Write "<tr>"
    Response.Write "<td>" & rst("word").Value & "</td>"
    Response.Write "<td>" & rst("language").Value & "</td>"
    Response.Write "<td>" & rst("english_equiv").Value & "</td>"
    Response.Write "</tr>"
    rst.MoveNext
Loop
Response.Write "</table>"
rst.Close
Set rst = Nothing
con.Close
Set con = Nothing
%>
<h2>Add a new entry:</h2>
<form action="<% Response.Write Request.ServerVariables("SCRIPT_NAME") %>" method="POST">
<table>
    <tr>
        <td align="right">word:</td>
        <td><input type="text" name="word"></td>
    </tr>
    <tr>
        <td align="right">language:</td>
        <td><input type="text" name="language"></td>
    </tr>
    <tr>
        <td align="right">english_equiv:</td>
        <td><input type="text" name="english_equiv"></td>
    </tr>
    <tr>
        <td></td>
        <td align="center"><input type="submit" value="Submit"></td>
    </tr>
</table>
</body>
</html>

从Access数据库中名为[vocabulary]的表开始

当我们加载ASP页面时，我们看到

如果我们为俄语单词添加新条目

然后点击“提交”页面将刷新

如果我们检查Access中的表格，我们会看到

重要提示

请注意，您不应将Access数据库用作Web应用程序的后端数据存储; Microsoft 强烈建议不要这样做（参考：here）。

捕获Unicode文本（Cyrillic）并将其插入MS Access数据库

1 个答案:

重要提示