Question

我正在尝试实现客户端服务器程序。服务器使用以下代码设置侦听套接字：

gen_tcp：listen（端口，[二进制，{active，true}]）

问题是当客户端向服务器发送大消息（元组列表）时，服务器会接收多条消息。似乎TCP正在将长消息分成几条消息。

我们如何处理以立即获得整个长消息？

Answer 1

我不认为tcp包是分裂的，我使用以下程序测试它。

client.erl

-module(client).
-compile(export_all).

send(Message) ->
    {ok, Socket} = gen_tcp:connect("localhost", 1234, [binary, {packet, 4}]),
    ok = gen_tcp:send(Socket, list_to_binary(Message)),
    gen_tcp:close(Socket).


main() ->
    Message = ["atom" ++ integer_to_list(X) || X <- lists:seq(1, 1000)],
    send(Message).

server.erl

-module(server).
-compile(export_all).

start()->
    {ok, ListenSocket} = gen_tcp:listen(1234, [binary, {packet, 4}, 
                     {active, true}, {reuseaddr, true}]),
    spawn(fun() -> per_connect(ListenSocket) end).

per_connect(ListenSocket) ->
    {ok, Socket} = gen_tcp:accept(ListenSocket),
    spawn(fun() -> per_connect(ListenSocket) end),
    loop(Socket).

loop(Socket) ->
    receive
        {tcp, Socket, Data} ->
            io:format("~p~n", [binary_to_list(Data)]),
            loop(Socket);
        {tcp_closed, Socket} ->
            io:format("closed~n"),
            gen_tcp:close(Socket)
    end.

您可以先运行server:start().，然后运行client:main()，即可看到结果。

在Erlang中向gen_tcp服务器发送大消息

1 个答案: