Question

我正在使用多线程TCP服务器。在主线程中，我在套接字上侦听并为新的传入连接创建一个新线程。我想将所有传入连接保存在哈希中，以便我可以从另一个线程访问它们。

从监视器线程，我无法读取任何新添加的连接。在创建监视器线程时，似乎会创建一个新的客户端哈希。

如何保留所有套接字的列表并将其从我的监视器线程中循环？

当前代码：

#!/usr/bin/perl
use strict;
use IO::Socket;
use threads;
use Thread::Queue;

# init
my $clients = {};
my $queue = Thread::Queue->new;

# thread that monitors
threads->create("monitor");

# create the listen socket
my $listenSocket = IO::Socket::INET->new(LocalPort  => 12345,
                                      Listen   => 10,
                                      Proto   => 'tcp',
                                      Reuse   => 1);

# make sure we are bound to the port
die "Cant't create a listening socket: $@" unless $listenSocket;

print "Server ready. Waiting for connections on 34567 ... \n";

# wait for connections at the accept call
while (my $connection = $listenSocket->accept) {
    # set client socket to non blocking
    my $nonblocking = 1;
    ioctl($connection, 0x8004667e, \\$nonblocking);

    # autoflush
    $connection->autoflush(1);

    # debug
    print "Accepted new connection\n";

    # add to list
    $clients->{time()} = $connection;

    # start new thread and listen on the socket
    threads->create("readData", $connection);
}

sub readData {
     # socket parameter
     my ($client) = @_;

     # read client
     while (<$client>) {
      # remove newline
      chomp $_;

  # add to queue
      $queue->enqueue($_);
     }

     close $client;
}

sub monitor {
    # endless loop
    while (1) {

        # loop while there is something in the queue
        while ($queue->pending) {

            # get data from a queue
            my $data = $queue->dequeue;

            # loop all sockets
            while ( my ($key, $value) = each(%$clients) ) {

               # send to socket
               print $value "$data\n";

            }
        }

        # wait 0,25 seconds
        select(undef, undef, undef, 0.25);
    }
}

close $listenSocket;

Answer 1

您需要通过threads::shared的$clients分享share：

my $clients = &share({});

旧式语法是由于Perl原型的记录问题。如果您有at least Perl 5.8.9，请使用更好的

my $clients = shared_clone({});

代替。

您还希望使用锁定保护$clients ，例如，

my $clients_lock : shared;
{
  lock $clients_lock;
  $clients->{time()} = fileno $connection;
}

最后，由于IO::Socket::INET个实例是Perl typeglobs，因此无法共享它们，因此请将其套接字描述符（从fileno）添加到$clients然后再添加fdopen

时必要时使用套接字

open my $fh, ">&=", $sockdesc or warn ...

以下程序将入站数据重复到其他连接的套接字：

#!/usr/bin/perl

use strict;
use IO::Socket;
use threads;
use threads::shared;
use Thread::Queue;

# init
my $clients = &share({});
my $clients_lock : shared;

my $queue = Thread::Queue->new;

# thread that monitors
threads->create("monitor");

# create the listen socket
my $port = 12345;
my $listenSocket = IO::Socket::INET->new(
  LocalPort  => $port,
  Listen     => 10,
  Proto      => 'tcp',
  Reuse      => 1
);

# make sure we are bound to the port
die "Can't create a listening socket: $@" unless $listenSocket;

print "Server ready. Waiting for connections on $port ... \n";

# wait for connections at the accept call
while (my $connection = $listenSocket->accept) {
  # set client socket to non blocking
  my $nonblocking = 1;
  ioctl($connection, 0x8004667e, \\$nonblocking);

  # autoflush
  $connection->autoflush(1);

  # debug
  print "Accepted new connection\n";

  # add to list
  {
    lock $clients_lock;
    $clients->{time()} = fileno $connection;
  }

  # start new thread and listen on the socket
  threads->create("readData", $connection);
}

sub readData {
  # socket parameter
  my ($client) = @_;

  # read client
  while (<$client>) {
    chomp;
    $queue->enqueue($_);
  }

  close $client;
}

sub monitor {
  # endless loop
  while (1) {
    # loop while there is something in the queue
    while ($queue->pending) {
      # get data from a queue
      my $data = $queue->dequeue;

      # loop all sockets
      {
        lock $clients_lock;
        while ( my ($key, $value) = each(%$clients) ) {
          # send to socket
          if (open my $fh, ">&=", $value) {
            print $fh "$data\n";
          }
          else {
            warn "$0: fdopen $value: $!";
          }
        }
      }
    }

    # wait 0,25 seconds
    select(undef, undef, undef, 0.25);
  }
}

close $listenSocket;

Answer 2

在Perl中使用线程没有太多经验，但我认为您只想分享您的客户列表：

    use threads::shared;
    my $clients : shared = {};

<小时/>

<强>更新

Perl抱怨：

my $hash : shared = {};

但似乎没问题：

my $hash = {};
share($hash);

此外，此代码：

my $hash = { key1 => "value1" };
share($hash);

似乎清除了哈希表，但是

my $hash = {};
share($hash);
$hash->{key1} = "value1";

就像我期望的那样。

如何在散列中保存套接字并从另一个线程循环它们？

2 个答案: