Question

在Excel中可以做这样的事情吗？

A列保留用于检查特定项目（通过键入X）。在B列中，有集合的名称，在C列中有特定的书籍。如果用户检查集合中的至少一本书，则应检查整个集合。

如果只有一个“根”单元格，那将非常简单，其他人只需要参考。问题是，用户可以检查集合中的任何单元格，然后进行循环引用。

到目前为止我还没有使用过宏，所以在这个问题上我总是新手。

Answer 1

以下事件宏将监控列 A 中的更改。如果已在 A 列中输入“X”，则宏会从 B 列中选取设置名称，并在列中查找此设置名称的其他实例乙即可。如果找到，“X”将放在 A

列中

Private Sub Worksheet_Change(ByVal Target As Range)
    Dim A As Range, nB As Long, B As Range, r As Range
    Dim v As String
    Set A = Range("A:A")
    If Intersect(Target, A) Is Nothing Then Exit Sub
    If Target.Count <> 1 Then Exit Sub
    If Target.Value <> "X" Then Exit Sub
    nB = Cells(Rows.Count, "B").End(xlUp).Row
    Set B = Range("B1:B" & nB)
    Application.EnableEvents = False
    v = Target.Offset(0, 1).Text
    For Each r In B
        If r.Text = v Then
            r.Offset(0, -1).Value = "X"
        End If
    Next r
    Application.EnableEvents = True
End Sub

因为它是工作表代码，所以很容易安装和自动使用：

右键单击Excel窗口底部附近的选项卡名称
选择查看代码 - 这会打开一个VBE窗口
粘贴内容并关闭VBE窗口

如果您有任何疑虑，请先在试用工作表上试用。

如果保存工作簿，宏将随之保存。如果您在2003年之后使用的是Excel版本，则必须保存该文件为.xlsm而不是.xlsx

删除宏：

按上述方式调出VBE窗口
清除代码
关闭VBE窗口

要了解有关宏的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/getstarted.htm

和

http://msdn.microsoft.com/en-us/library/ee814735(v=office.14).aspx

要了解有关事件宏（工作表代码）的更多信息，请参阅：

http://www.mvps.org/dmcritchie/excel/event.htm

必须启用宏才能使其生效！

在范围内共享Excel单元格值

1 个答案: