Question

我正在尝试在Prolog（gnu）中编写一个小程序，该程序将接受用户输入，并对“这个语法中这是一个有效的句子吗？”这个问题给出真或假。我在Prolog上找到可靠的文档时遇到了很多麻烦，如果有人有可靠的来源，我将不胜感激。根据我的发现，这段代码大部分都应该有效。当我试图追踪执行时，我得到了一些我不理解的奇怪结果。

我正在使用的测试用例是当用户输入'a =（b + c）'时。问题是从我的列表中删除最后一项是导致重做循环，我不确定为什么。

% Grammar:
% <assign> → <id> = <expr>
% <expr> → <id> <op> <expr>
%        | ( <expr> )
%        | <id>  
% <op> → * | + | / | - 
% <id> → a | b | c 

op('+').
op('-').
op('*').
op('/').


id(a).
id(b).
id(c).
id('a').
id('b').
id('c').
id([a]).
id([b]).
id([c]).



%
% Determine if the Sentence is valid according to the grammar
%
% param (in): Sentence - A list of symbols that make up the sentence to be evaluated
%
assign(Sentence) :-
  list(Sentence), length(Sentence, Length), >=(Length, 3),   %precondition test
  =(Sentence, [First, Second | Tail] ),
  id(First),
  =(Second, '='),
  expr(Tail).

% Test if the list of symbols is a valid expression
expr(X) :-
  length(X, Length), Length >= 1,
  =(X, [First | Tail] ),

  ( Length = 1 ->
      id(X)

  ; Length >= 3, =(First,'(') ->
    =(Tail, [Second | Tail2] ),
    last(Last, Tail),
    append(Middle, [_], Tail),

    =(Last, ')'),
    expr(Middle)

  ; =(Tail, [Second | Tail2] ),
    id(First), 
    op(Second),
    expr(Tail2)
  ).

%
% Input a sentence, then decompose it into a list of symbols. 
% User input should be quoted, e.g., Enter a sentence: 'A = B * C'
%
% param (out): SentenceList  The list of symbols input by the user is bound to this variable
%
read_sentence(SentenceList) :-
   print('Enter a sentence: '),
   read_token(Input),
   write_term_to_chars(InputList, Input, []),
   delete(InputList, ' ', SentenceList).

%
% Start the program
%
start :-
  read_sentence(Sentence),
  assign(Sentence).

Answer 1

Prolog的语法使得符号处理更简单。以下是我编写代码的方法：

assign([First, '=' | Expr]) :-
    id(First),
    expr(Expr).

expr([First | Tail]) :-
    id(First), 
    right(Tail).
expr(['(' | Rest]) :-
    append(Expr, [')'|Follow], Rest),
    expr(Expr),
    right(Follow).

right([]).
right([Op|Expr]) :-
    op(Op),
    expr(Expr).

注意使用模式匹配，而不是基于长度/ 2的程序检查等

assign([First, '=' | Expr]) :-
...

这意味着：如果参数是第二个位置带有'='的列表，并且尾部是我们命名为Expr的列表，则使用此子句。

（关于语法：经常我们不需要引用原子，但规则有点复杂。例如，这是一个有效的查询

?- assign([c,=,a,+,b]).

这里不需要引用原子，因此代码可以是assign([First, = | Expr]) :- ...）

然后身体对第一个列表元素（即id（第一个））和Expr发出相应的检查。

为了获得括号之间的Expr，我使用了惯用法

expr(['(' | Rest]) :-
    append(Expr, [')'|Follow], Rest),
...

仅当Rest包含Expr后跟'）'时，此追加/ 3才能成功。

我认为您的原始方法错过了right(Follow). 我们需要它，因为语法是递归的，在运算符之后......

Prolog循环重做

1 个答案: