Question

我是shaders的新手，但我一直在关注一些教程，我在这个特殊的着色器上尝试了很多东西......但是无济于事。

我从here获得了代码。该着色器随着时间的推移循环2个纹理，具有“擦除”效果（请参阅演示源）。现在我已经学会了并且理解了大部分内容，我正在尝试将其更改为能够使用带有alpha的纹理。

这是着色器代码：

Shader "Wipe" {

Properties{
    _tex0 ("Texture1", 2D) = "white" {}
    _tex1 ("Texture2", 2D) = "white" {}
}

SubShader{
    Tags {"Queue"="Geometry"}

    Pass{
    CGPROGRAM
    #pragma target 3.0
    #pragma vertex vert
    #pragma fragment frag
    #include "UnityCG.cginc"

    sampler2D _tex0;
    sampler2D _tex1;
    float4 _tex0_ST;

    struct v2f {
        float4 pos : POSITION;
        float4 color : COLOR0;
        float4 fragPos : COLOR1;
        float2 uv : TEXCOORD0;
    };

    v2f vert (appdata_base v){
        v2f o;
        o.pos = mul (UNITY_MATRIX_MVP, v.vertex);
        o.fragPos = o.pos;
        o.uv = TRANSFORM_TEX (v.texcoord, _tex0);
        o.color = float4 (1.0, 1.0, 1.0, 1);
        return o;
    }

    half4 frag (v2f i) : COLOR{
        float animtime = _Time*10.0;
        float2 q = i.uv.xy / float2(1,1);
        float3 oricol = tex2D (_tex0,float2(q.x,q.y)).xyz;
        float3 col = tex2D (_tex1,float2(i.uv.x,i.uv.y)).xyz;
        float comp = smoothstep( 0.2, 0.7, sin(animtime) );
        col = lerp(col,oricol, clamp(-2.0+2.0*q.x+3.0*comp,0.0,1.0));

        // custom alpha bit
        float4 textureColor = float4(col,1);
        if(textureColor.a < 1.0){
            discard;
        }

        return textureColor;
    }
    ENDCG
    }
}
//FallBack "VertexLit"
}

我尝试在最后一个alpha支持函数中实现一个小代码片段。我尝试将标签更改为{“Queue”=“Transparent”“IgnoreProjector”=“True”“RenderType”=“Transparent”}，将Cull和ZWrite设置为Off，添加Blend SrcAlpha OneMinusSrcAlpha ...基本上尝试丢弃透明片段，alpha测试和混合，但我一定做错了。

我将两个纹理（PSD，Photoshop文件格式与Alpha）设置为“高级”纹理类型，关闭“生成Mip贴图”，打开“Alpha is Transparency”，将“Format”设置为“RGBA” 32位“。通过上面的这些设置和着色器，我的纹理可以预览，但我的纹理平面是黑色的......

任何人都可以帮助我或向我提供正确的方向吗？

提前致谢！

编辑：（对不起链接，我还没有足够的声誉发布所有内容）

这是我使用未经编辑的着色器从here + PSD设置为正常（没有高级纹理设置）： http：//answers.unity3d.com/storage/temp/22441-unity_base.jpg

这是我使用当前着色器（上面的代码）+ PSD作为纹理，设置为RGBA 32位，没有Mip贴图和'Alpha is Transparency'打开时得到的： http：//answers.unity3d.com/storage/temp/22442-unity_black.jpg

这就是我想要实现的目标（但不是静止图像，我想保持原来的“擦拭”效果）： http：//nicolasraspail.com/unity_achieve.png

编辑：这是着色器正常工作（感谢@nwellnhof！）

    Shader "Wipe" {

        // Editor controllers
        Properties{
        _tex0 ("Texture1", 2D) = "white" {}
        _tex1 ("Texture2", 2D) = "white" {}
        }

    SubShader{
        Tags {"Queue"="Transparent" "IgnoreProjector"="True" "RenderType"="Transparent"}
        ZWrite Off
        Blend SrcAlpha OneMinusSrcAlpha

        Pass{
        CGPROGRAM
            #pragma target 3.0
            #pragma vertex vert
            #pragma fragment frag
            #include "UnityCG.cginc"

            sampler2D _tex0;
            sampler2D _tex1;
            float4 _tex0_ST;

            struct v2f {
                float4 pos : POSITION;
                float4 color : COLOR0;
                float4 fragPos : COLOR1;
                float2  uv : TEXCOORD0;
            };

            v2f vert (appdata_base v){
                v2f o;
                o.pos = mul (UNITY_MATRIX_MVP, v.vertex);
                o.fragPos = o.pos;
                o.uv = TRANSFORM_TEX (v.texcoord, _tex0);
                o.color = float4 (1.0, 1.0, 1.0, 1);
                return o;
            }

            half4 frag (v2f i) : COLOR{
                float4 oricol   = tex2D(_tex0, i.uv);
                float4 col      = tex2D(_tex1, i.uv);
                float  animtime = _Time * 10.0;
                float  comp     = smoothstep(0.2, 0.7, sin(animtime));
                float  coeff    = clamp(-2.0 + 2.0 * i.uv.x + 3.0 * comp, 0.0, 1.0);
                float4 result   = lerp(col, oricol, coeff);

                return result;
            }
        ENDCG
}
}
//FallBack "VertexLit"
}

Answer 1

好吧，如果_tex1中的颜色是透明的，您对片段程序的更改会丢弃整个片段。这不会产生预期的效果。您应该做的是撤消更改，只需使用float4代替float3作为颜色变量，并在分配结束时删除.xyz。那就是：

    float4 oricol = tex2D (_tex0,float2(q.x,q.y));
    float4 col = tex2D (_tex1,float2(i.uv.x,i.uv.y));

但是整个程序可以简化很多。类似下面的内容应该是等效的（未经测试）：

half4 frag (v2f i) : COLOR {
    float4 oricol   = tex2D(_tex0, i.uv);
    float4 col      = tex2D(_tex1, i.uv);
    float  animtime = _Time * 10.0;
    float  comp     = smoothstep(0.2, 0.7, sin(animtime));
    float  coeff    = clamp(-2.0 + 2.0 * i.uv.x + 3.0 * comp, 0.0, 1.0);
    float4 result   = lerp(col, oricol, coeff);

    return result;
}

为片段着色器添加alpha支持（GLSL）

1 个答案: