Question

我正在使用delphi 7并制作小程序，其中我使用webbrowser从id中获取值

这里是保存值的HTML示例

<div id="download" style="display: block;">

    <a style="display:none" href="blablabla"></a>
    <a href="Need This value"></a>
    <a style="display:none"blablabla"></a>
    <a style="display:none"blablabla"></a>
    <span style="margin-left:8px; color:#808080; overflow:hidden; white-space: nowrap"></span>
</div>

我可以获得id“下载”的innerHTML 我的问题是如何从标签“a”获得“href”的值

Answer 1

如果相关的<a>代码分配了name或id，您可以简单地使用IHTMLDocument2.anchors集合来查找它，例如：< / p>

var
  Doc: IHTMLDocument2;
  Anchor: IHTMLAnchorElement;
  Value: String;
begin
  Doc := WebBrowser1.Document as IHTMLDocument2;
  Anchor := Doc.anchors.item('name', 0) as IHTMLAnchorElement;
  Value := Anchor.href;
end;

但是，由于它没有name或id，您将不得不进一步深入挖掘DOM，例如：

var
  Doc: IHTMLDocument3;
  Download: IHTMLElement;
  Coll: IHTMLElementCollection;
  Anchor: IHTMLAnchorElement;
  Value: String;
begin
  Doc := WebBrowser1.Document as IHTMLDocument3;
  Download := Doc.getElementById('download') as IHTMLElement;
  Coll := Download.children as IHTMLElementCollection;
  Coll := Coll.tags('a') as IHTMLElementCollection;
  Anchor := Coll.item(1, 0) as IHTMLAnchorElement;
  Value := Anchor.href;
end;

Answer 2

不知道这是否是最好的解决方案，但它在这里有效：

function FindYourValue(block : string) : string;
var text, subtext : string;
    quant : integer;
begin
  text := block;
  if pos('<a href="',text) > 0 then
    subtext := copy(text,pos('<a href="',text) + 9,length(text));
  quant := pos('"',subtext);
  result := copy(subtext,1,9);
end;

BLOCK是从<div id="download" style="display: block;">例程获得的字符串。

Answer 3

Remy Lebeau @RemyLebeau提供的解决方案应该可行。但是，如果HTML不包含您期望的元素，则可能会遇到异常。如果您想以更安全的方式编写代码，我建议您使用Supports来查询Html元素接口。

function ExtractUrlExample: TStringList; 
var
  Doc: IHTMLDocument3;
  Download: IHTMLElement;
  Coll: IHTMLElementCollection;
  I: Integer;
  Anchor: IHTMLAnchorElement;
begin
  Result := TStringList.Create;
  if Supports(WebBrowser1.Document, IHTMLDocument3, Doc) and
     Supports(Doc.getElementById('download'), IHTMLElement, Download) and
     Supports(Download.children, IHTMLElementCollection, Coll) and
     Supports(Coll.tags('a'), IHTMLElementCollection, Coll) then
  begin
    for I := 0 to Coll.Length - 1 do
      if Supports(Coll.item(I, 0), IHTMLAnchorElement, Anchor) then
        Result.Add(Anchor.href); // The Url you want to extract
  end;
end;

Delphi webbrowser - 如何从id中的标记名获取值

3 个答案: