Question

我正在编写一个裸机ARM启动加载程序，我正在尝试使用一些内部SRAM作为暂存区来与应用程序代码进行通信。根据我的需要，我不需要初始化或清零内存。使用这个脚本，我可以将我想要的变量放在内存中。

/**
 * Linker script for secondary bootloader.
 *
 * Allocatest the first 1Mb of DRAM for its use.
 * Scratchpad in internal SRAM.
 */

MEMORY
{
    SRAM : o = 0x402F0400, l = 0x0000FC00  /* 63kB available internal SRAM */
    DDR0 : o = 0x80000000, l = 1M          /* 1Mb external DDR Bank 0 */
}

OUTPUT_FORMAT("elf32-littlearm", "elf32-littlearm", "elf32-littlearm")
OUTPUT_ARCH(arm)

SECTIONS
{
    .startcode :
    {
        __AppBase = .;
        . = ALIGN(4);
        *init.o      (.text)
    } >DDR0

    .text :
    {
        . = ALIGN(4);
        *(.text*)
        *(.rodata*)
    } >DDR0

    .data :
    {
        . = ALIGN(4);
        *(.data*)
    } >DDR0

    .bss :
    {
        . = ALIGN(4);
        _bss_start = .;
        *(.bss*)
        *(COMMON)
        _bss_end = .;
    } >DDR0

    .stack :
    {
        . = ALIGN(4);
        __StackLimit = . ;
        *(.stack*)
        . = __AppBase + 1M;
        __StackTop = .;
    } >DDR0
    _stack = __StackTop;

    .internal_ram :
    {
        . = ALIGN(4);
        *(.internal_ram*)
    } >SRAM
}

使用objcopy创建原始二进制文件时，我收到了大量文件。我假设这是因为原始二进制文件的第一个字节实际上是内部存储器，在.text部分的开头有几兆字节的填充。 Objdump -h显示internal_ram部分标有CONTENTS，LOAD和DATA标志，即使放在那里的变量没有初始化。

我可以使用--remove-section = .internal_ram在objcopy中清理它，但似乎应该有一种方法让链接器识别数据未初始化。

有没有办法正确标记该部分？

Answer 1

正确的部分声明是：

.internal_ram (NOLOAD) :
{
    . = ALIGN(4);
    *(.internal_ram*)
} >SRAM

NOLOAD部分属性已记录在案，但就加载时处理该部分的程序加载器而言。起初，这似乎不适用于裸机图像，但为此目的，objcopy就像一个程序加载器，并尊重目标文件中的标志设置，省略了原始图像中的部分。

GNU链接器标记部分没有LOAD的初始化数据 - 原始二进制巨大

1 个答案: