Question

XML文件可以有1000 - 6000个表单; XML文件二可以有一到100个或更多。我想用文件二替换文件一中的任何相同的表单。如果它存在于文件2中而不存在于文件1中，我想将其添加到文件1.合并文件后，我想对我的XSLT运行它。我正在使用2.0样式表和撒克逊语解析器。

文件1：

<Forms> <Form name="fred" date="10/01/2008"/> <Form name="barney" date="12/31/2009"/> <Form name="wilma" date="12/31/2010"/> </Forms>

文件2：

<Forms> <Form name="barney" date="01/31/2010"/> <Form name="betty" date="6/31/2009"/> </Forms>

合并文件应如下所示：

<Forms> <Form name="fred" date="10/01/2008"/> <Form name="barney" date="01/31/2010"/> <Form name="wilma" date="12/31/2010"/> <Form name="betty" date="6/31/2009"/> </Forms>

Answer 1

如果维护文档顺序不是优先事项：

<xsl:variable name="forms1" select="document('forms1.xml')/Forms/Form" />
<xsl:variable name="forms2" select="document('forms2.xml')/Forms/Form" />

<xsl:variable name="merged" select="
  $forms1[not(@name = $forms2/@name)] | $forms2
" />

<xsl:template match="/">
  <xsl:apply-templates select="$merged" />
</xsl:template>

<xsl:template match="Form">
  <!-- for the sake of the example; you can use a more specialized template -->
  <xsl:copy-of select="." />
</xsl:template>

如果因任何原因维护文件顺序是优先考虑的事情......

<xsl:template match="/">
  <!-- check values of file 1 sequentially, and replace them if needed -->
  <xsl:for-each select="$forms1">
    <xsl:variable name="this"  select="." />
    <xsl:variable name="newer" select="$forms2[@name = $this/@name]" />
    <xsl:choose>
      <xsl:when test="$newer">
        <xsl:apply-templates select="$newer" />
      </xsl:when>
      <xsl:otherwise>
        <xsl:apply-templates select="$this" />
      </xsl:otherwise>
    </xsl:choose>
  </xsl:for-each>
  <!-- append any values from file 2 that are not in file 1 -->
  <xsl:apply-templates select="$forms2[not(@name = $forms1/@name)]" />
</xsl:template>

使用XSLT合并两个XML源文档

1 个答案: