Question

我需要删除此xmlvia xslt

中的文件路径

<?xml version="1.0" encoding="ISO-8859-1"?>
    <InvoiceCapture>
    <Invoice>
        <CaptureDate>2014-02-19</CaptureDate>
        <CaptureTime>14:04:07</CaptureTime>
        <Company>bygg</Company>
        <Type>0</Type>
        <Supplier>11111111</Supplier>
        <SupplierInvoiceNo>11111111</SupplierInvoiceNo>
        <InvoiceDate>2013-12-30</InvoiceDate>
        <DueDate>2014-01-29</DueDate>
        <Reference1>11111111</Reference1>
        <Reference2>11111111</Reference2>
        <Currency>SEK</Currency>
        <Amount>11111111</Amount>
        <VatAmount>11111111</VatAmount>
        <AlternativeID>20140219_bygg_2788</AlternativeID>
        <ImageFile>\\extsql1\INVOICES\m3Bygg\test\2KB16000.PNG  \\extsql1\INVOICES\m3Bygg\test\2KB16002.PNG \\extsql1\INVOICES\m3Bygg\test\2KB16004.PNG \\extsql1\INVOICES\m3Bygg\test\2KB16006.PNG \\extsql1\INVOICES\m3Bygg\test\2KB16008.PNG</ImageFile>
        <NoOfImages>5</NoOfImages>
        <BatchPrefix/>
        <BatchNo>2788</BatchNo>
        <InvoiceLine/>
    </Invoice>
</InvoiceCapture>

我需要的输出只是用空格分隔的图像名称：

<ImageFile>2JE04000.PNG 2JE04002.PNG 2JE04004.PNG 2JE04006.PNG 2JE04008.PNG</ImageFile>

Answer 1

我的建议是这个模板，我打电话给extract-substrings-between。它的优点是使用单个模板完成任务，不需要特定于此实际问题的扩展，并且通常更有用。

其参数为：

string ：待处理字符串。它默认为应用了normalize-space()的当前节点的值。
startCharacter和endCharacter：该模板会提取既不包含startCharacter也不包含endCharacter的子字符串，但会立即显示一个startCharacter或字符串的开头，后面跟着endCharacter或字符串的结尾。 startCharacter和endCharacter都默认为空格。
outputSeparator：正如名称所示，字符串将输出的提取子字符串分开。也默认为空格。

<强>样式表

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="1.0">
  <xsl:template match="/">
    <xsl:for-each select="InvoiceCapture/Invoice/ImageFile">
      <xsl:copy>
        <xsl:call-template name="extract-substrings-between">
          <xsl:with-param name="startCharacter" select="'\'"/>
        </xsl:call-template>
      </xsl:copy>
    </xsl:for-each>
  </xsl:template>

  <xsl:template name="extract-substrings-between">
    <xsl:param name="string" select="normalize-space()"/>
    <xsl:param name="startCharacter" select="' '"/>
    <xsl:param name="endCharacter" select="' '"/>
    <xsl:param name="outputSeparator" select="' '"/>

    <xsl:variable name="currentToken" 
      select="substring-before(concat($string, $endCharacter), $endCharacter)"/>

    <xsl:choose>
      <xsl:when test="contains($currentToken, $startCharacter)">
        <!-- We need to chip off more from the current token -->
        <xsl:call-template name="extract-substrings-between">
          <xsl:with-param name="string" select="substring-after($string, $startCharacter)"/>
          <xsl:with-param name="startCharacter" select="$startCharacter"/>
          <xsl:with-param name="endCharacter" select="$endCharacter"/>
          <xsl:with-param name="outputSeparator" select="$outputSeparator"/>
        </xsl:call-template>
      </xsl:when>

      <xsl:otherwise>
        <!-- We've isolated what we want to return from the current token -->
        <xsl:value-of select="$currentToken"/>

        <xsl:variable name="remainingString" select="substring-after($string, ' ')"/>
        <xsl:if test="$remainingString != ''">
          <xsl:value-of select="$outputSeparator"/>
          <xsl:call-template name="extract-substrings-between">
            <xsl:with-param name="string" select="$remainingString"/>
            <xsl:with-param name="startCharacter" select="$startCharacter"/>
            <xsl:with-param name="endCharacter" select="$endCharacter"/>
            <xsl:with-param name="outputSeparator" select="$outputSeparator"/>
          </xsl:call-template>
        </xsl:if>
      </xsl:otherwise>
    </xsl:choose>
  </xsl:template>

</xsl:stylesheet>

<强>输出：

<ImageFile>2KB16000.PNG 2KB16002.PNG 2KB16004.PNG 2KB16006.PNG 2KB16008.PNG</ImageFile>

Answer 2

您的预期输出不再与您的输入XML匹配。不过，正如我所说，下面是XSLT 1.0中的解决方案 - 这很难。像tokenize()这样的函数在XSLT 1.0中不可用，并且您不能将结果树片段本身用作节点集。我的解决方案使用EXSLT将结果树片段转换为节点集。

仅当文件路径相似且最后包含“\ test \”时才有效。

<强>样式表

<?xml version="1.0" encoding="utf-8"?>

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:exsl="http://exslt.org/common"
                extension-element-prefixes="exsl">

   <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

    <xsl:strip-space elements="*"/>

   <xsl:template match="//ImageFile">
    <xsl:copy>
       <xsl:variable name="tokens">
           <xsl:call-template name="tokenize">
               <xsl:with-param name="string" select="."/>
           </xsl:call-template>
       </xsl:variable>
       <xsl:for-each select="exsl:node-set($tokens)/*">
           <xsl:value-of select="substring-after(.,'\test\')"/>
           <xsl:text>&#32;</xsl:text>
       </xsl:for-each>
    </xsl:copy>
   </xsl:template>

   <xsl:template name="tokenize">
    <xsl:param name="string" select="."/>
    <xsl:param name="separator" select="' '"/>
    <xsl:choose>
        <xsl:when test="not(contains($string, $separator))">
            <item>
                <xsl:value-of select="normalize-space($string)"/>
            </item>
        </xsl:when>
        <xsl:otherwise>
            <item>
                <xsl:value-of select="normalize-space(substring-before($string, $separator))"/>
            </item>
            <xsl:call-template name="tokenize">
                <xsl:with-param name="string" select="substring-after($string, $separator)"/>
            </xsl:call-template>
        </xsl:otherwise>
    </xsl:choose>
   </xsl:template>

   <xsl:template match="text()"/>

</xsl:stylesheet>

<强>输出

<ImageFile>2KB16000.PNG  2KB16002.PNG 2KB16004.PNG 2KB16006.PNG 2KB16008.PNG </ImageFile>

Answer 3

假设路径实际上是由制表符（	）字符分开（很难从复制的示例中分辨出来），并且不是假设有关除{{1}以外的路径的任何内容}分隔符，请尝试以下样式表：

XSLT 1.0：

从字符串中删除重复出现的值

3 个答案: