Question

以下是我输入的XML文件的片段：

<p>List:
<ul>
<li>a</li>
<li>b</li>
<li>c</li>
</ul>This is a list</p>

我需要在输出XML中将其显示为：

<p>List:</p>
<ul>
<li>a</li>
<li>b</li>
<li>c</li>
</ul><p>This is a list</p>

我通过简单地编码p标签来做到这一点，从长远来看这并不是有益的。假设没有"This is a list"，那么它给了我这个：

<p>List:</p>
<ul>
<li>a</li>
<li>b</li>
<li>c</li>
</ul><p></p>

该文件有效但我不需要空的p标记。

Answer 1

试试这个：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:xs="http://www.w3.org/2001/XMLSchema" exclude-result-prefixes="xs" version="2.0">

<xsl:template match="p">
    <xsl:apply-templates/>
</xsl:template>

<xsl:template match="p/text()">
    <p><xsl:value-of select="."/></p>
</xsl:template>

<xsl:template match="ul">
    <xsl:copy-of select="."/>
</xsl:template>
</xsl:stylesheet>

Answer 2

这是使用xsl:for-each-group

的那个

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

<xsl:template match="@*|node()">
    <xsl:copy>
        <xsl:apply-templates select="@*|node()"></xsl:apply-templates>
    </xsl:copy>
</xsl:template>

<xsl:template match="p">
    <xsl:for-each-group select="node()" group-adjacent="if (self::text()) then 1 else 0">
        <xsl:choose>
            <xsl:when test="current-grouping-key()">
                <p><xsl:copy-of select="current-group()"/></p>
            </xsl:when>
            <xsl:otherwise>
                <xsl:copy-of select="current-group()"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:for-each-group>
</xsl:template>

</xsl:stylesheet>

XSLT：特定标记放置

2 个答案: