Question

这从XML to XML using XSL Problem延伸我根据解决方案（感谢Kyle Butt）设法导入exslt并修改了我的代码，如下所示：

<xsl:stylesheet version="1.0"
              xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
              xmlns:func="http://exslt.org/functions"
              xmlns:set="http://exslt.org/sets"
              extension-element-prefixes="set">

<xsl:import href="set.distinct.function.xsl"/>

<xsl:output method="xml" indent="yes"/>

<xsl:template match="gallery">
  <gallery>
    <xsl:variable name="gallery" select="."/>
    <xsl:for-each select="set:distinct(photo/tag/event)">
      <xsl:value-of select="."/>
      <event name="{.}">
        <xsl:variable name="event" select="." />
        <xsl:for-each select="set:distinct($gallery/object/tag[event=.]/group)">
          <group name="{.}">
            <xsl:variable name="group" select="." />
            <xsl:apply-templates select="$gallery/object[tag/event=$event][tag/group=$group]" />
          </group>
        </xsl:for-each>
      </event>
    </xsl:for-each>
  </gallery>
</xsl:template>

但是输出中的错误 - '功能设置：distinct（）失败了。值不能为空。'怎么解决这个问题？

Btw XML输入：

<gallery>
  <photo>
    <tag>
      <event>Birthday</event>
      <group>Family</group>
      <other>Swensens</other>
    </tag>
  </photo>
  <photo>..</photo>
</gallery>

＆安培;必需的XML输出：

<gallery>
  <event name="Birthday">
    <group name="Family">
      <photo>
        <tag>
         <other>Swensens</other>
        </tag>
      </photo>
      <photo>..</photo>
    </group>
    <group>..</group>
  </event>
  <event>..</event>
</gallery>

Answer 1

当我按原样在你的输入上运行你的XSL时，我没有收到错误，但这是我得到的输出：

<gallery>
  Birthday
  <event name="Birthday"/>
</gallery>

所以这里有很多事情没有让你达到你想要的输出。有一件事是你只是输出事件的名称作为库节点的值，所以要摆脱它你要删除＆lt; xsl：value-of select =“。” /＆GT;在第一个xsl：for-each中（可能是这个调试代码吗？）

然后在事件中查看xsl：for-each中的这一部分：

<xsl:variable name="event" select="." />
<xsl:for-each select="set:distinct($gallery/object/tag[event=.]/group)">

我在集合中看到了XPath的一些问题：distinct：

您提供的XML输入中的gallery节点下方的节点是＆lt; photo＆gt;，而您的XPath中有“对象”。
您没有使用$ event变量来检查事件节点 - 标记上的谓词应该是[event = $ event]。

这些是导致你看到的错误的原因 - XPath没有选择任何东西，因此你在null上调用set：distinct。

所以进行这些修正后，得到的输出是：

<gallery>
  <event name="Birthday">
    <group name="Family"/>
  </event>
</gallery>

然后XP中的＆lt; xsl：apply-templates select =“$ gallery / object [tag / event = $ event] [tag / group = $ group]”/＆gt;需要将对象更改为照片。在我的样式表中，我添加了一个匹配照片的模板，因为它没有包含在样本样式表中，所以我的样式表现在看起来像：

<xsl:stylesheet version="1.0"
          xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
          xmlns:func="http://exslt.org/functions"
          xmlns:set="http://exslt.org/sets"
          extension-element-prefixes="set">
<xsl:output method="xml" indent="yes"/>

<xsl:template match="gallery">
  <gallery>
    <xsl:variable name="gallery" select="."/>
    <xsl:for-each select="set:distinct(photo/tag/event)">
      <event name="{.}">
        <xsl:variable name="event" select="." />
        <xsl:for-each select="set:distinct($gallery/photo/tag[event=$event]/group)">
          <group name="{.}">
            <xsl:variable name="group" select="." />
            <xsl:apply-templates select="$gallery/photo[tag/event=$event][tag/group=$group]" />
          </group>
        </xsl:for-each>
      </event>
    </xsl:for-each>
  </gallery>
</xsl:template>

<xsl:template match="photo">
  <photo>
    <tag>
      <xsl:copy-of select="tag/*[not(name(.)='group') and not(name(.)='event')]" />
    </tag>
  </photo>
</xsl:template>
</xsl:stylesheet>

我得到的输出是：

<gallery>
  <event name="Birthday">
    <group name="Family">
      <photo>
        <tag>
          <other>Swensens</other>
        </tag>
      </photo>
    </group>
  </event>
</gallery>

多田!!

如何使用Exslt解决XML到XML问题 - set：distinct

1 个答案: