Question

我的新Arduino Uno + WifiShield出了问题。我想测试arduino.cc或Arduino-IDE“WifiChatServer”提供的示例代码：

#include <SPI.h>
#include <WiFi.h>

char ssid[] = "ssid"; //  your network SSID (name) 
char pass[] = "password";    // your network password (use for WPA, or use      as key for WEP)

int keyIndex = 0;            // your network key Index number (needed only for WEP)

int status = WL_IDLE_STATUS;

WiFiServer server(23);

boolean alreadyConnected = false; // whether or not the client was connected previously

void setup() {
  //Initialize serial and wait for port to open:
  Serial.begin(9600); 
  while (!Serial) {
    ; // wait for serial port to connect. Needed for Leonardo only
  }

  // check for the presence of the shield:
  if (WiFi.status() == WL_NO_SHIELD) {
    Serial.println("WiFi shield not present"); 
   // don't continue:
    while(true);
  } 

  // attempt to connect to Wifi network:
  while ( status != WL_CONNECTED) { 
    Serial.print("Attempting to connect to SSID: ");
    Serial.println(ssid);
    // Connect to WPA/WPA2 network. Change this line if using open or WEP network:    
    status = WiFi.begin(ssid, pass);

    // wait 10 seconds for connection:
    delay(10000);
  } 
  // start the server:
  server.begin();
  // you're connected now, so print out the status:
  printWifiStatus();
 }


void loop() {
 // wait for a new client:
  WiFiClient client = server.available();


  // when the client sends the first byte, say hello:
   if (client) {
    if (!alreadyConnected) {
      // clead out the input buffer:
      client.flush();    
      Serial.println("We have a new client");
      client.println("Hello, client!"); 
      alreadyConnected = true;
    } 

    if (client.available() > 0) {
      // read the bytes incoming from the client:
      char thisChar = client.read();
       // echo the bytes back to the client:
      server.write(thisChar);
      // echo the bytes to the server as well:
      Serial.write(thisChar);
    }
  }
}


void printWifiStatus() {
  Serial.print("SSID: ");
  Serial.println(WiFi.SSID());

  // print your WiFi shield's IP address:
  IPAddress ip = WiFi.localIP();
  Serial.print("IP Address: ");
  Serial.println(ip);

  // print the received signal strength:
  long rssi = WiFi.RSSI();
  Serial.print("signal strength (RSSI):");
  Serial.print(rssi);
  Serial.println(" dBm");
}

您还可以在此处查找代码：http://arduino.cc/en/Tutorial/WiFiChatServer

除了输入我的家庭wifi连接数据外，我没有做任何更改。将代码上传到我的arduino后，控制器连接到wifi并打印他的ip-address，由我的路由器分配。此外，arduino列在路由器上已连接设备的表中。

从笔记本电脑上ping arduino是成功的！

尝试通过telnet（putty）连接到arduino时会显示错误“Connection Refused”。我尝试连接我的笔记本电脑上的禁用防火墙，使用另一个端口（8888/9999）和我的智能手机，每次都出现同样的错误。

这是wireshark捕获一个简单的ping和telnet请求：http://imagizer.imageshack.us/v2/800x600q90/34/ayo5.png

有人有想法解决这个问题吗？

Answer 1

我有一些类似的问题（使用官方的wifi防护罩）。我使用早期版本的Arduino IDE解决了这个问题。我将其从1.0.5降级到1.0.3并且有效。也许你有同样的问题？

至少值得一试！

Answer 2

使用Arduino 1.05我遇到了同样的问题。我刚刚将Arduino 1.0.4中的WiFi库复制到Arduino 1.0.5中，它可以工作。

Answer 3

I seem to have copied an example-code, where the server.begin(); was missing. So make sure your implementation is complete.

Arduino Uno + WifiShield：Telnet错误“连接被拒绝”

3 个答案: