Question

我的XML中包含以下内容：

<MyElement> Cats&amp;apos; eyes </ MyElement >

当我在XSLT 1.0中使用以下代码时：

<xsl:value-of select="MyElement" />

输出

Cats&apos; eyes

但我想得到

Cats’ eyes

我试过

<xsl:value-of select='translate(MyElement, "&amp;apos; ", "&apos; ")'  />

但是它不起作用，结果是一些消除字符的结果!!!!

有什么想法吗？

由于

Answer 1

您的第一个问题是，您的内容似乎已被“双重转义”。撇号的实体是'，而不是&apos;。

您尝试使用 translate() 替换字符不起作用，因为它的工作方式与您预期的不同。它不是查找/替换方法。您可以在第二个参数中指定字符列表，然后在第三个参数中将相应的字符转换为相应的字符。如果第三个参数中的字符列表中没有相应的字符，那么它将被删除。

您需要使用recursive template来执行角色替换。

例如：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:template match="/">
        <xsl:call-template name="replace-string">
            <xsl:with-param name="text" select="MyElement"/>
            <xsl:with-param name="replace" select="'&amp;apos;'"/>
            <xsl:with-param name="with" select='"&apos;"'/>
        </xsl:call-template>
    </xsl:template>

    <xsl:template name="replace-string">
        <xsl:param name="text"/>
        <xsl:param name="replace"/>
        <xsl:param name="with"/>
        <xsl:choose>
            <xsl:when test="contains($text,$replace)">
                <xsl:value-of select="substring-before($text,$replace)"/>
                <xsl:value-of select="$with"/>
                <xsl:call-template name="replace-string">
                    <xsl:with-param name="text"
                        select="substring-after($text,$replace)"/>
                    <xsl:with-param name="replace" select="$replace"/>
                    <xsl:with-param name="with" select="$with"/>
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$text"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:template>
</xsl:stylesheet>

当然，使用XSLT 2.0，您只需使用replace()函数：

<xsl:sequence select='replace(MyElement, "&amp;apos;", "&apos;")'/>

Answer 2

这很简单，只需添加disable-output-escaping="yes"

即可

<xsl:value-of select="MyElement" disable-output-escaping="yes"/>

XSLT 1.0无法翻译撇号

2 个答案: