Question

这里我的函数将cmd作为Rebol指令执行：

exec-cmd: func [
        cmd [ block! ] "Rebol instructions"
        /local err
] [
        if error? err: try [
                do cmd
        ] [ print mold disarm err ]
]

当我启动该功能时，我遇到以下错误消息：

** Script Error: err needs a value
** Where: exec-cmd
** Near: if error? err: try [
    do cmd
]

如何避免此消息并管理错误？

Answer 1

使用set/any和get/any来处理常规分配和评估无法实现的值。

if error? set/any 'err try [
    do cmd
] [ print mold disarm get/any 'err ]

一旦解除了错误，您就可以正常处理。

Answer 2

当Rebol默认评估程序看到SET-WORD的序列时！后跟一个“完整”表达式，它将该表达式的结果赋值给指定的单词。

然而，Rebol能够从一个名为UNSET的函数中返回一种特殊的“无”。例如：

>> type? print {What "value" does a print return?}
What "value" does a print return?
== unset!

这与返回NONE不同！值...因为如果继续评估链，评估者将不允许他们进行分配。

>> foo: print {This isn't legal}
This isn't legal
** Script Error: foo needs a value
** Near: foo: print "This isn't legal"

变量实际上不能“保持UNSET！类型的值”。 UNSET！只是您尝试访问未设置的变量时将获得的“值类型”。无论是否存在无价值的哲学等价，机械后果是如果你想允许未设置！要有效地“分配”的价值，您必须使用set函数和/any细化来执行“分配”：

>> set/any 'foo (print {This works...})
This works...
== unset!

但是为了能够从值中读取，您不能仅仅引用它，因为变量现在是未定义的。您需要使用相应的get：

>> type? get/any 'foo
== unset!

无论如何，这就是为什么你会看到这个的背景。你的cmd可能以一个返回UNSET的函数结束了！就像print一样？

以下是一个可能具有说明性的示例：

exec-cmd: func [
    cmd [block!] "Rebol instructions"
    /local err
] [
    set/any 'result (try [do cmd])
    case [
        unset? get/any 'result [
            print "Cmd returned no result"
        ]

        function? :result [
            print ["Cmd returned a function:" newline (mold :result)]
        ]

        ;-- Rebol3 only --
        ;
        ; closure? :result [
        ;    print ["Cmd returned a closure:" newline (mold :result)]
        ; ]

        ;-- Rebol3 should be changed to match Red and not require this --
        ;
        lit-word? :result [
            print ["Cmd returned a literal word:" newline (mold :result)]
        ]

        error? result [
            print mold disarm result
        ]

        true [
            print ["Cmd returned result of type" (mold type? result)]
            print ["The value was:" newline (mold result)]
        ]
    ]
]

请注意，一旦您已经处理了可能未设置结果的情况，您就不必使用get/any并且只能进行正常访问。

解释器的工作方式存在一个基本问题，即如果一个单词被绑定到一个FUNCTION！ value（也是Rebol3中的CLOSURE！值）然后引用该单词调用相关代码。要解决这个问题，如果你知道你的某个单词可能具有这样的值，你可以使用GET或SET-WORD的类似物！被称为GET-WORD！这些通常被认为是“丑陋的”，所以最好是你可以隔离需要测试这种边缘情况的代码部分，而不是把冒号放在你不需要的东西前面！

被认为是设计缺陷的东西被称为“点亮字衰变”。这需要使用GET-WORD！在Rebol2中，如果你手中有一个实际的字面词。在这种情况下，你的程序不会崩溃，它只是不会给你你期望的。 It's explained here ...它已在Red中更改，因此肯定会更改为Rebol3。

此外，在Rebol3中已经消除了错误被“武装”并需要被“解除”以进行检查的概念。这不会影响Rebol2中的error?测试，因此您需要使用GET-WORD !,但会影响您可以使用它们执行的所有操作。

好的。我想想我已经涵盖了这里的所有案例，但如果我没有，有人会纠正我！

（注意：如果你很好奇如何制作自己的函数来返回UNSET！就像打印一样，只需使用exit代替return）

>> nothing: func [value] [exit]

>> type? nothing 1020
== unset!

当我使用错误？并尝试，错误需要一个价值

2 个答案: