是否可以将VirtualStringTree导出到Excel或CSV?
我正在使用Delphi 2007并尝试将我的VirtualStringTree数据记录保存为Excel或CSV格式。
答案 0 :(得分:3)
CSV会更容易。
您的数据是您自己的数据,因为VirtualStringTree不包含数据,它是一个虚拟容器。因此,如果您的虚拟字符串树是TMyObjects列表(容器)的视图,则输出到CSV应该相对简单,并且如果您的列可能处于不同的顺序,则虚拟树的内容才真正重要,或者完成了可见的列集。
我建议您研究免费的JVCL JvCsvDataSet,这是一种非常简单的CSV文件写入方式。
如果你真的想要XLS输出,那就有库。
答案 1 :(得分:2)
我们有一个ExcelWriter
辅助类,可以将所有类型的东西转储到Excel中,例如。
在这种情况下,快速方式(并且易于复制粘贴)是可以将变量数组转储到Excel中的重载:
class function TExcelWriter.ExportToExcelVariantArray(const VArray: Variant; const Title, SubTitle: WideString): Boolean;
var
xl: OleVariant;
workbook: OleVariant;
worksheet: OleVariant;
range: OleVariant;
Rowcount, ColumnCount: Integer;
HeaderRowIndex: Integer;
s: WideString;
begin
Result := False;
if not VarIsArray(VArray) then
raise EExcelWriterException.Create('ExportToExcelVariantArray: Supplied variant is not an array');
if VarArrayDimCount(VArray) <> 2 then
raise EExcelWriterException.Create('ExportToExcelEVariantArray: Supplied variant array does not have 2 dimensions ('+IntToStr(VarArrayDimCount(VArray))+')');
ColumnCount := VarArrayHighBound(VArray, 2) - VarArrayLowBound(VArray, 2); //2 for "leftmost dimension"
rowCount := VarArrayHighBound(VArray, 1) - VarArrayLowBound(VArray, 1); //1 for "leftmost dimension"
try
xl := CreateOleObject('Excel.Application');
except
on E:Exception do
begin
if (E is EOleSysError) then
begin
if EOleSysError(E).ErrorCode = CO_E_CLASSSTRING then
raise EExcelWriterException.Create('Excel is not installed.'+CRLF+
'Could not load "Excel.Application" object (Co_E_CLASSSTRING)')
else
raise;
end
else
raise;
end;
end;
try
xl.ScreenUpdating := False;
xl.DisplayAlerts := False; // Don't display dialogs such as "save changes to workbook".
workbook := xl.Workbooks.Add;
try
Worksheet := Workbook.Worksheets[1];
try
Worksheet.Activate;
Worksheet.Cells.WrapText := False;
HeaderRowIndex := 1; //Rows&Columns in Excel start at one.
range := TExcelWriter.GetRange(worksheet, HeaderRowIndex, 1, HeaderRowIndex+RowCount, ColumnCount);
range.Value := VArray;
//Bold the header row
Worksheet.Rows[HeaderRowIndex].Font.Bold := True;
Worksheet.Rows[HeaderRowIndex].Font.Underline := True;
Worksheet.Columns.AutoFit;
//Set printed header&footer
if Copy(Title, 1, 2) = '@@' then
s := Copy(Title, 3, MaxInt)
else
s := Title;
if SubTitle <> '' then
begin
if s <> '' then s := s+#13;
s := s + SubTitle;
end;
TExcelWriter.SetHeaderAndFooters(Worksheet,
s, '', '',
'&D &T', '', 'Page &P of &N');
finally
Worksheet := Unassigned;
end;
finally
Workbook := Unassigned;
end;
//When all done
xl.ScreenUpdating := True;
xl.Visible := True;
xl.UserControl := True; // Very important, prevents Excel from going
// away when we nil out our reference to it below.
finally
xl := Unassigned;
end;
Result := True;
end;
我们有TVirtualListView
TVirtualStringTree
后代,可以轻松过渡到VirtualTrees(它有TVirtualListItem
等)。然后它有一个辅助方法ContentToVariantArray
,类似于ContentToHtml
和ContentToRtf
:
function TVirtualListView.ContentToVariantArray: Variant;
var
Columns: TColumnsArray;
VArray: Variant;
Node: PVirtualNode;
ColumnCount: Integer;
RowCount: Integer;
nRow: Integer;
i: Integer;
begin
Columns := Self.Columns.GetVisibleColumns;
ColumnCount := Length(Columns);
RowCount := Self.Items.Count+1; //+1 for the heaader
VArray := VarArrayCreate([0, RowCount-1, 0, ColumnCount-1], varOleStr); //Docs say cannot use varString, must be varOleStr (which is a BSTR i.e. WideString)
nRow := 0;
for i := 0 to ColumnCount-1 do
begin
VArray[nRow, i] := Self.Columns.Items[Columns[i].Index].Text;
end;
Node := Self.GetFirst;
while Assigned(Node) do
begin
Inc(nRow);
for i := 0 to ColumnCount-1 do
begin
VArray[nRow, i] := Self.Text[Node, Columns[i].Index];
end;
Node := Self.GetNextSibling(Node);
end;
Result := VArray;
end;
这里的主要缺点是我们要自动化Excel才能使用它。这意味着您的客户/服务器将需要安装Excel。
上面的代码显示了用户Excel(必须将文件保存到硬盘驱动器只是为了查看它是浪费),而不是创建导出文件。但是,调用.Save
或无论API是什么都不难。
答案 2 :(得分:1)
构建CSV(与html相同):
var ss : AnsiString;
...
if ExtractFileExt(DestFileName)='.htm'
then
ss:=VST.ContentToHtml(tstAll, 'Html exp')
else
ss:=VST.ContentToText(tstAll, ';');
with TFileStream.Create(DestFileName, fmCreate or fmShareDenyWrite) do
begin
Write(ss[1], length(ss));
Free;
end;