Question

我在.emacs文件中输入了以下代码，以突出显示不需要的空格。

(require 'whitespace)
(setq whitespace-style '(face empty tabs lines-tail trailing))
(global-whitespace-mode t)

这显示（1）开头的空行＆amp;缓冲结束（2）标签（3）超过80个字符限制的行（4）尾随空格

我希望emacs自动突出显示'2个或更多空行'。有关如何实现这一点的任何想法？我确实找到了blog post在regexp的帮助下解释了一种方法，但我不知道如何在.emacs文件中实现它。

编辑1：找到一种删除多余空行的方法，但这仍然无法自动突出显示多个空白行。 delete extra blank lines in emacs

编辑2：将以下内容添加到.emacs似乎可以正常工作，但只有在我在缓冲区中保存并重新打开文件后才能使用。

(add-hook 'change-major-mode-hook '(lambda () (highlight-regexp "\\(^\\s-*$\\)\n" 'hi-yellow)))

编辑3：在编辑2中的行之前将。{1}}添加到.emacs文件后，它似乎突出显示缓冲区中的一个或多个空行。我不知道如何修改regexp以便它只接受2个或更多空行。

Answer 1

您的highlight-regexp - 解决方案可以使用以下elisp（例如，在您的.emacs文件中）进入辅助模式。

您可以通过右键单击模式行中的某个模式名称然后选择nl2-mode来激活次要模式。您可以点击模式行中的nl2并选择Turn off minor mode来停用次要模式。

要理解代码，请参阅define-minor-mode和define-key的帮助（例如， C-h f define-minor-mode RET ）。请注意，在emacs中，菜单中的鼠标点击也算作击键。

(define-minor-mode nl2-mode
  "Highlight two successive newlines."
  :global t
  :lighter " nl2"
  (if nl2-mode
      (highlight-regexp "\\(^\\s-*$\\)\n" 'hi-yellow)
    (unhighlight-regexp "\\(^\\s-*$\\)\n")))

(define-key mode-line-mode-menu [nl2-mode]
  `(menu-item ,(purecopy "nl2-mode") nl2-mode
  :help "Highlight two succesive newlines."
  :button (:toggle . (bound-and-true-p nl2-mode))))

有几个事实突出显示两个连续的空行更复杂（font-lock往往只突出显示非空区域，换行符是区域重新定义的限制，需要缓冲区更改后的重新确定）。以下代码显示了一种方法。也许，有更简单的方法。

(require 'font-lock)
(global-font-lock-mode)

(defface jit-lock-nl2-face '((default :background "yellow"))
  "Face to indicate two or more successive newlines."
  :group 'jit-lock)

(defun jit-nl2-extend (start end &optional old)
  "Extend region to be re-fontified"
  (save-excursion
    (save-match-data
      ;; trailing:
      (goto-char end)
      (skip-chars-forward "[[:blank:]]\n")
      (setq jit-lock-end (point))
      ;; leading:
      (goto-char start)
      (beginning-of-line)
      (skip-chars-backward "[[:blank:]]\n")
      (unless (bolp) (forward-line))
      (setq jit-lock-start (point)))))

(defun jit-nl2 (jit-lock-start jit-lock-end)
  "Highlight two or more successive newlines."
  (save-excursion
    (save-match-data
      (jit-nl2-extend jit-lock-start jit-lock-end)
      ;; cleanup
      (remove-text-properties jit-lock-start jit-lock-end '(font-lock-face jit-lock-nl2-face))
      ;; highlight
      (while (< (point) jit-lock-end)
    (if (looking-at "[[:blank:]]*\n\\([[:blank:]]*\n\\)+")
        (progn (put-text-property (match-beginning 0) (match-end 0) 'font-lock-face 'jit-lock-nl2-face)
           (goto-char (match-end 0)))
      (forward-line))))))


(add-hook 'after-change-major-mode-hook (lambda ()
                      (add-hook 'jit-lock-after-change-extend-region-functions 'jit-nl2-extend)
                      (jit-lock-register 'jit-nl2)
                      (jit-lock-mode 1)
                      ))

Answer 2

只需使用库Highlight（highlight.el）。这就是它的用途。

使用命令hlt-highlight-regexp-region（C-x X h x）或hlt-highlight-regexp-to-end（C-x X h e）。（要取消高亮显示正则表达式，请使用C-x X u x或C-x X u e。）

交互式地，您输入正则表达式以在Emacs中使用（使用C-q C-j来匹配换行符，并且不需要双反斜杠），因此您键入$^\s-*$$ C-q C-j。

Emacs：突出显示2个或更多空行

2 个答案: