Question

我有一个问题让我头疼得厉害。请帮我。输入是：

<body>
 <p class="section"> section 1 </p>
 <p class="code"> some code </p>
 <p class="code"> following code </p>
 <p class="code"> following code </p>
 <p class="section"> section 2 </p>
 <p class="code"> other code </p>
 <p class="code"> following code </p>
 <p class="code"> following code </p>
 <p class="section"> section 3 </p>
 <p class="code"> still other code </p>
 <p class="code"> following </p>
 <p class="code"> following </p>
</body>

我想要的输出：

<body>
 <p class="section"> section 1 </p>
 <pre> some code following code following code </pre>
 <p class="section"> section 2 </p>
 <pre> other code following code following code </pre>
 <p class="section"> section 3 </p>
 <pre> still other code following following </pre>
</body>

问题是要折叠到<pre>标记所有相邻的<p class="code">标记。没有办法使用XSLT执行此操作。你认为存在解决方案吗？

Answer 1

您无需重建XML，请查看此处：XSLT Grouping Siblings。

Answer 2

使用XSLT 2.0，您可以按如下方式使用for-each-group-group：

<xsl:stylesheet
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  version="2.0">

  <xsl:output indent="yes"/>

  <xsl:template match="@* | node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="body">
    <xsl:copy>
      <xsl:for-each-group select="*" group-adjacent="boolean(self::p[@class = 'code'])">
        <xsl:choose>
          <xsl:when test="current-grouping-key()">
            <pre>
              <xsl:apply-templates select="current-group()/node()"/>
            </pre>
          </xsl:when>
          <xsl:otherwise>
            <xsl:apply-templates select="current-group()"/>
          </xsl:otherwise>
        </xsl:choose>
      </xsl:for-each-group>
    </xsl:copy>
  </xsl:template>

</xsl:stylesheet>

您可以将XSLT 2.0与Saxon 9或AltovaXML tools一起使用。

Answer 3

这样的事情应该有效：

<xsl:template match="body">
    <xsl:apply-templates select="p[@class='section']" />
</xsl:template>

<xsl:template match="p[@class='section']">
    <xsl:copy-of select="."/>
    <pre>
        <xsl:variable name="code" select="following-sibling::p[@class='code']" />
        <xsl:for-each select="following-sibling::p">
            <xsl:variable name="index" select="position()"/>
            <xsl:if test="generate-id(.)=generate-id($code[$index])">
                <xsl:value-of select="."/>
            </xsl:if>
        </xsl:for-each>
    </pre>
</xsl:template>

Answer 4

问题是您的XML结构不够简单，无法用于简单的XSLT解决方案。

不同的“部分”并没有真正以易于提取的方式进行设置。如果您可以控制输入XML，请查看是否可以将其更改为：

<body>
 <p class="section"> section 1 
  <p class="code"> some code </p>
  <p class="code"> following code </p>
  <p class="code"> following code </p>
 </p>
 <p class="section"> section 2
  <p class="code"> other code </p>
  <p class="code"> following code </p>
  <p class="code"> following code </p>
 </p>
 <p class="section"> section 3
  <p class="code"> still other code </p>
  <p class="code"> following </p>
  <p class="code"> following </p>
 </p>
</body>

这将允许您为“部分”定义xsl-template，其中您可以xsl-foreach覆盖“代码”类。

使用XSLT合并相邻的兄弟节点

4 个答案: