Question

我想要做的就是转换，例如

(define count-suits (symbol-map-function hearts diamonds clubs spades))

到

(define count-suits (λ (#:hearts hearts
                        #:diamonds diamonds
                        #:clubs clubs
                        #:spades spades)
                       (make-hash (cons 'hearts hearts)
                                  (cons 'diamonds diamonds)
                                  (cons 'clubs clubs)
                                  (cons 'spades spades))))

我有lambda的身体与

一起工作

(define-syntax (generate-symbol-map stx)
  (syntax-case stx ()
    ((gen...map enumerations ...)
     #'(make-hash (cons (quote enumerations) enumerations) ...))))

但是我有一个时间生成的魔鬼

(λ (#:hearts hearts
    #:diamonds diamonds
    #:clubs clubs
    #:spades spades)

这是我到目前为止所拥有的

;; e.g. (weave '(1 3 5 7) '(2 4 6 8)) = '(1 2 3 4 5 6 7 8)
;; tested, works.
(define-for-syntax (weave list1 list2)
  (cond ((empty? list1) list2)
        ((empty? list2) list1)
        (else (list* (car list1)
                     (car list2)
                     (weave (cdr list1)
                            (cdr list2))))))

(define-syntax (symbol-map-function stx)
  (syntax-case stx ()
    ((sym...ion symbols ...)
     ; What I'm trying to do here is splice the result of weaving the keywords,
     ; generated by format-id, with the symbols themselves, e.g. in the case of
     ; (symbol-map-function foo bar baz):
     ;   #`(λ (#,@(weave '(#:foo #:bar #:baz) '(foo bar baz)))
     ;   --> #`(λ (#,@'(#:foo foo #:bar bar #:baz baz))
     ;   --> #`(λ (#:foo foo #:bar bar #:baz baz)
     ; I am using syntax-unquote-splicing because I am in syntax-quasiquote and the
     ; result of the expression is a list that I want to be spliced into the arguments.
     #`(λ (#,@(weave (list (syntax-e (format-id #'symbols
                                                "#:~a"
                                                (syntax-e #'symbols))) ...)
                     (list #'(symbols ...))))
          (generate-symbol-map symbols ...)))))

(list (syntax-e (format-id #'symbols "#:~a" (syntax-e #'symbols))) ...)意味着导致

(list (syntax-e (format-id #'foo "#:~a" (syntax-e #'foo)))
      (syntax-e (format-id #'bar "#:~a" (syntax-e #'bar)))
      (syntax-e (format-id #'baz "#:~a" (syntax-e #'baz))))

但我被告知我在＃符号之后缺少省略号。我试过以不同的方式玩代码，但没有任何真正的目的或洞察力，我没有偶然发现任何有用的东西。

Answer 1

...无法显示在模板之外，这意味着它们必须显示在#'之前的symbols部分内。您可以写#'(symbols ...)但不能#'symbols ...。

在此之后，您可能希望使用syntax->list，它将您的语法对象转换为语法对象列表。

此外，您无法使用format-id生成关键字，因为format-id会将结果强制为符号，并且会将生成的ID括在管道中：

> (require racket/syntax)
> (format-id #'here "#:~a" 'auie)
#<syntax |#:auie|>

所以你需要使用syntax->datum，symbol->string，然后string->keyword来做你想做的事。

这是一个有效的例子：

#lang racket
(require (for-syntax racket/syntax racket/list))

(define-syntax (foo stx)
  (syntax-case stx ()
    [(_ (sym ...) body ...)
     (with-syntax ([kws (flatten
                         (map (λ(k)
                                (list
                                 (string->keyword
                                  (symbol->string 
                                   (syntax->datum k)))
                                 k))
                              (syntax->list #'(sym ...))))]
                   )
       #'(λ kws body ...))]))

; Test:
((foo (aa bb)
     (list aa bb))
 #:bb 'bbb
 #:aa 'aaa)
; -> '(aaa bbb)

Answer 2

这是symbol-map-function：

的有效实施

(require (for-syntax racket/list))
(define-syntax (symbol-map-function stx)
  (define (id->keyword id)
    (datum->syntax id (string->keyword (symbol->string (syntax-e id)))))
  (syntax-case stx ()
    ((_ id ...)
     (andmap identifier? (syntax->list #'(id ...)))
     (with-syntax ((lambda-list (append-map (lambda (id)
                                              (list (id->keyword id) id))
                                            (syntax->list #'(id ...)))))
       #'(lambda lambda-list
           (make-hash `((id . ,id) ...)))))))

我希望我知道组装lambda列表比使用append-map更好的方法;改进欢迎。： - ）

在语法案例中绊倒语法 - 引用 - 拼写，模板变量和省略号

2 个答案: